#! /usr/bin/env perl
use Sys::Hostname;
use LWP::UserAgent;
use Getopt::Long;
use DBI;
use Sys::Syslog;
use strict;
use warnings;
my $hostname = hostname;

sub usage {
    die "usage: $0 [FLAGS] --campaign=CAMPAIGN --plugin=PLUGIN --version=VERSION [--where=WHERE]

FLAGS
  --premium          # don't add --skip-plugins to wpcli command
  --skip-suspended
  --skip-wordfence
  --skip-backup
  --verbose          # print commands before running them
  --force            # pass onto wp-cli
  --install=URL      # 'wp plugin install URL'

CAMPAIGN
  A unique identifier for related plugin upgrades, for tracking purposes.

PLUGIN
  The plugin 'slug', as it appears in the database or wp-content/plugins path,
  or wordpress.org URL, f.e.
    themegrill-demo-importer (for ThemeGrill Demo Importer)
    wordpress-seo (for Yoast SEO)
    wpforms-lite (for Contact Form by WPForms)

WHERE
  Arbitrary SQL syntax that's injected into the query used to select
  plugins to upgrade. No care is taken to avoid SQL injections.

  The base query:
    SELECT user,db,root FROM plugins WHERE plugin='plugin'

  The query with --where=\"pver <> '3.9.4'\":
    SELECT user,db,root FROM plugins WHERE plugin='plugin' AND pver <> '3.9.4'

VERSION
  Now *required* unless ill-advised --minor or --patch arguments are used.
  Stats only syslogged with --version=
";
}

my $statuskey = 'aJcb55pgZ1ir6Y';
my $cphp = '/opt/cpanel/ea-php72/root/usr/bin/php';
my (%options, %wfence, $version);
my ($upgrades, $misses) = (0, 0);
my $now = time;
GetOptions(
    "campaign=s" => \$options{campaign},
    "skip-suspended" => \$options{skipsuspended},
    "skip-wordfence" => \$options{skipwordfence},
    "skip-backup" => \$options{skipbackup},
    "plugin=s" => \$options{plugin},
    "where=s" => \$options{where},
    "minor" => \$options{minor},
    "patch" => \$options{patch},
    "version=s" => \$options{version},
    "premium" => \$options{premium},
    "verbose" => \$options{verbose},
    "force" => \$options{force},
    "install=s" => \$options{install},
) or usage;
usage unless defined $options{plugin} && defined $options{campaign} && $options{campaign} =~ /^[\w-]+$/;
$options{where} = "AND $options{where}" if defined $options{where};
$options{where} = "" unless defined $options{where};
$version = "--minor" if defined $options{minor};
$version = "--patch" if defined $options{patch};
$version = "--version=$options{version}" if defined $options{version};
usage unless defined $version;
my $skip = "--skip-plugins --skip-themes";
$skip = "--skip-themes" if defined $options{premium};
my $force = defined $options{force} ? "--force" : "";

my $dbh = DBI->connect("dbi:SQLite:dbname=/var/lib/eig/dc/plugins", undef, undef, { RaiseError => 1 });

if ($options{skipwordfence}) {
    %wfence = map { @$_, 1 } @{$dbh->selectall_arrayref("SELECT distinct root FROM plugins WHERE plugin='wordfence'")};
}

for (@{$dbh->selectall_arrayref("SELECT distinct user,db,root FROM plugins WHERE plugin='$options{plugin}' $options{where}")}) {
    my ($user, $db, $root) = @$_;
    next if $options{skipsuspended} && -f "/var/cpanel/suspended/$user";
    next if $options{skipwordfence} && exists $wfence{$root};
    chdir $root or do { warn "not able to cd to $root -- skipping upgrade"; next };
    upgrade($user, $db, $root, $options{plugin});
}

sub backupfile {
    my ($user, $db) = @_;
    my $name = "/home/$user/$db.$now.sql";
    return $name if -d "/home/$user/";
    my @pwent = getpwnam($user);
    return $name unless @pwent; # will fail to open for writing
    return $pwent[7]."/$db.$now.sql";
}

sub backup {
    my ($user, $db) = @_;
    my $name = backupfile($user, $db);
    return 1 if -f $name; # we've got a duplicate upgrade somehow
    open my $f, '>', $name or do {
        warn "Failed to open $name for writing : $!";
        return 0;
    };
    chmod 0600, $name or do {
        warn "Failed to chmod 0600 $name : $!";
        close $f;
        unlink $name;
        return 0;
    };
    open my $dump, '-|', 'mysqldump', $db or do {
        warn "Failed to mysqldump $db for $user : $!";
        close $f;
        unlink $name;
        return 0;
    };
    while (defined(my $line = <$dump>)) {
        print {$f} $line;
    }
    close $dump;
    close $f;
    system gzip => $name;
    print "Backup: $name.gz\n";
    return 1
}

sub upgrade {
    my ($user, $db, $root, $plugin) = @_;
    if ($root =~ /["\n!]/) { warn "skipping suspect docroot: $root"; next } # paranoia
    if ($plugin =~ /["\n!']/) { warn "skipping suspect plugin: $root"; next } # paranoia
    my $shell = "su - $user -s /bin/bash -c";
    my $wpcli = qq{/usr/local/bin/wp --path="$root"};
    $wpcli = "$cphp $wpcli" if -x $cphp;

    print qq{$shell "$wpcli plugin status $plugin $skip|grep Version:"}, "\n" if defined $options{verbose};
    chomp(my $pre = qx{$shell "$wpcli plugin status $plugin $skip|grep Version:"});
    if (!defined($options{install}) && $pre !~ /\(Update available\)/) {
        print "WP-MASS-UPGRADE UNABLE $user $root $pre\n";
        if (defined $options{version}) {
            $misses++ unless $pre =~ /\b\Q$options{version}\E\b/;
        }
        return;
    }
    unless ($options{skipbackup}) {
        backup($user, $db) or do {
            warn "Failed to back up $db for $root -- skipping upgrade\n";
            $misses++;
            return;
        };
    }

    if (defined $options{install}) {
        print qq{$shell "$wpcli plugin install $options{install} $force $skip"}, "\n" if defined $options{verbose};
        system qq{$shell "$wpcli plugin install $options{install} $force $skip"};
    } else {
        print qq{$shell "$wpcli plugin update $plugin $version $force $skip"}, "\n" if defined $options{verbose};
        system qq{$shell "$wpcli plugin update $plugin $version $force $skip"};
    }
    print qq{$shell "$wpcli plugin status $plugin $skip|grep Version:"}, "\n" if defined $options{verbose};
    chomp(my $post = qx{$shell "$wpcli plugin status $plugin $skip|grep Version:"});
    print "WP-MASS-UPGRADE $user $root $pre $post\n";
    if (defined $options{version}) {
        $post =~ /\b\Q$options{version}\E\b/ ? $upgrades++ : $misses++;
    }
}

if ($upgrades || $misses) {
    openlog 'PluginUpgrades', '', 'LOG_USER';
    print "WP-MASS-UPGRADE SYSLOG $options{plugin} with $upgrades upgrades, $misses misses\n";
    syslog 'notice', "$options{plugin} with $upgrades upgrades, $misses misses";
    my $ua = LWP::UserAgent->new;
    $ua->agent('wpmassupgrade');
    $ua->ssl_opts(verify_hostname => 0);
    $ua->timeout(10);
    my $res = $ua->post("https://reports.soc.newfold.com/report/wp-mass-upgrade?key=$statuskey&host=$hostname&campaign=$options{campaign}&plugin=$options{plugin}&version=$version&upgrades=$upgrades&misses=$misses");
    warn "[!] failed to report upgrade results to okd: ".$res->status_line unless $res->is_success;
}
