#!/usr/bin/perl
# Backup CPanel related files for account restores

use strict;
use YAML qw( DumpFile LoadFile );
use Sys::Hostname;
use Data::Dumper;

my $eig_backup_config_file = '/opt/eig_linux/etc/eig_backup.conf';
my $backup_server_config = '/opt/eig_linux/etc/backup_server_info.conf';
my $hostname = hostname();
my $logfile = "/var/log/eig_backup/update_user_list.log";

my %eig_backup_config;
my $hgbackupdir = "/admin/hgbackupdir";
open my $config, '<', $eig_backup_config_file
  or die "Unable to open EIG Backup config file $eig_backup_config_file for reading: $!";
while (<$config>) {
    chomp();
    $eig_backup_config{$1} = $2 if /^([^=]+?)=(.+)$/
}
close $config;

if ( -x "/opt/eig_linux/bin/backupstate" ) {
    system("/opt/eig_linux/bin//backupstate --submit");
}

open(LOG, ">>$logfile") || die "Can't open logfile: $logfile: \n";
print LOG localtime(time) . ": Updating active user list\n";

my $users;
my $homedir;

opendir(CPUSERS, "/var/cpanel/users");

foreach my $user ( readdir(CPUSERS) ) {
	next if ( $user =~ m/^(\.+|root)$/ );
	$homedir = (getpwnam($user))[7];
    next if !(defined $homedir);
	$users->{$1}->{$user} = 1 if ( $homedir =~ m/\/home(\d*)\// );
}
close CPUSERS;

# Set the values to repquota data if possible for DR purposes
my $userinfo;
foreach my $homenum (keys %$users){ 
    my $quotas = get_quota_usage($homenum); 
    foreach my $user (keys %{$users->{$homenum}}){ 
        $userinfo->{$user}->{active} = 1;
        $userinfo->{$user}->{partition} = $homenum; 
        $userinfo->{$user}->{diskusage} = $quotas->{$user} if defined $quotas->{$user}; 
    } 
} 

my $destination = $eig_backup_config{'non_user_data_location'} || '/home1';
if ( !-d "$destination/eig_backup_staging/dirs.files/cpbackup/daily/" ) {
	print LOG localtime(time) . ": Creating $destination/eig_backup_staging/dirs.files/cpbackup/daily/\n";
	system("mkdir", "-p", "$destination/eig_backup_staging/dirs.files/cpbackup/daily/") == 0 or die "Failed to create $destination/eig_backup_staging/dirs.files/cpbackup/daily/: $!\n";
}

if (-f "$destination/eig_backup_staging/dirs.files/cpbackup/daily/active_users"){
    my $old_users = LoadFile("$destination/eig_backup_staging/dirs.files/cpbackup/daily/active_users");
    foreach my $homenum (keys %$old_users){
    my @diff = grep(!defined $users->{$homenum}->{$_},keys %{$old_users->{$homenum}});
        if (scalar @diff){
            print LOG localtime(time) . ": The following users were not found on /home$homenum and will be archived:\n";
            print LOG join("\n",@diff) . "\n";
        }
    }
}

DumpFile("$destination/eig_backup_staging/dirs.files/cpbackup/daily/active_users", $users) || print LOG "Failed to dump YAML: $!\n";
DumpFile("$destination/eig_backup_staging/dirs.files/cpbackup/daily/userinfo", $userinfo) || print LOG "Failed to dump YAML: $!\n";

if ( $eig_backup_config{ssh_sync} ) {
    $backup_server_config = LoadFile( $backup_server_config ) or die "SSH rsync defined but unable to open backup server config file $backup_server_config for reading: $!";
}
die "No SSH host found in $backup_server_config to rsync to!\n" if ( !$backup_server_config->{backup_ip} );
my $non_user_data_location = 1;
$non_user_data_location = $1 if ( $eig_backup_config{'non_user_data_location'} =~ m/^\/home(\d*)$/ );

for my $file (qw(active_users userinfo)){ 
    my $rsync = "/usr/bin/ionice -c2 -n6 /opt/eig_linux/bin/rsync3 --rsync-path=/usr/bin/rsync --out-format=': /%f%L' --timeout=480 -xav --sparse --partial --bwlimit=8000 -e 'ssh -q -i $hgbackupdir/backupkey -F $hgbackupdir/ssh_config' $destination/eig_backup_staging/dirs.files/cpbackup/daily/$file  root\@$backup_server_config->{backup_ip}:/home/$hostname/backup$non_user_data_location/dirs.files/cpbackup/daily/$file";
    print LOG localtime(time) . ": rsync to run: $rsync\n";
    my $output = `$rsync`;
    print LOG localtime(time) . ": \n$output";
} 

print LOG localtime(time) . ": Complete\n";
close LOG;

# Parses repquota data for a given homenum
sub get_quota_usage { 
    my $homenum = shift; 
    my $mount; 
    if ($homenum =~ m/^\d+$/){ 
        $mount = "/home$homenum"; 
    } else { 
        $mount = `/bin/mountpoint /home` =~ m/is a mountpoint/ ? "/home" : "/"; 
    } 
    my $quotas; 
    foreach my $line ( `/usr/sbin/repquota $mount |sed '1,5d'` ){ 
        # imasample    --   50740   50740   50740 1439979464    4881  4881  4881 0
        my ($user, $blocks) =  (split(' ',$line))[0,2];
        next if !(defined $blocks && $blocks =~ m/^\d+$/);
        next if !(defined $user);
        $quotas->{$user} = sprintf("%.2f", $blocks / 1024 / 1024);
    }
    return $quotas;
} 
