#!/usr/bin/perl

BEGIN {

##   Commenting this out since we don't have SecBinLog on Rock
#    require '/usr/sec/lib/SecBinLog.pm';
#    SecBinLog::sb_log(); # Writes an entry to /var/log/legacy/sec-bin.log

}


use strict;

# Determine if eig_backup datacycle package is installed, otherwise fail to run script.
my $rpm_check = qx{ rpm --query eig_backup };
die "Required package eig_backup is not installed. Giving up at life." unless $rpm_check =~ /^eig_backup/;

$| = 1;
$ENV{'PATH'} = '';

################################################################################
sub eval_params($);
sub get_backups($);
sub get_DBs($);
sub list_backups($);

sub restore_DBs($);
sub show_usage();

################################################################################
#main
{
    my %h = (
        '_rt' => { 'debug'       => 0,
                   'use_epoch'   => 1,
                   'interactive' => 1,
                   'only_last'   => 1,
                   'pretend'     => 1,
                   'verbose'     => 0,
                 },
        '_bak'            => {},
        '_db'             => {},
        '_filt'           => {},
        '_rstor'          => [],
        '_mysql_bin'      => '/usr/bin/mysql -u root',
        '_mysqladmin_bin' => '/usr/bin/mysqladmin -u root',

        '_rExcluded'   => qr#^(\.|horde|roundcube)#,
        '_rUserDump'   => qr#^([\w-]+)#,
        '_rExistingDB' => qr#^\s*?(\S+)\s*?#,
        '_rExcludeDB'  => qr#^(Database)#,
        '_rParam'      => qr#^-+(\w+)#,
        '_rUserDB'     => qr#([a-zA-Z0-9]+)_[a-zA-Z0-9]+#,
        '_rBackupFile' => qr#(^/backup/cpbackup/[\w\/]+\.sql)$#,

            );
    if (@ARGV) {
        eval_params(\%h);
        if ($h{'_rt'}{'help'}) {
            show_usage();
        }
        else {
            if ($h{'_rt'}{'fixbackuplinks'}) {
                print "Running fixbackuplinks script\n" if ($h{'_rt'}{'verbose'});
                if (system('/opt/eig_linux/bin/fixbackuplinks') == 0) {
                    print "fixbackuplinks\t[OK]\n" if ($h{'_rt'}{'verbose'});
                }
                else {
                    warn $!;
                }
            }

            #List existing backups--------------------------------------------------
            elsif ($h{'_rt'}{'list'}) {
                get_backups(\%h);
                list_backups(\%h);
            }

            #restore db backups-----------------------------------------------------
            elsif ($h{'_rt'}{'restore'}) {
                get_backups(\%h);
                get_DBs(\%h);
                restore_DBs(\%h);
            }
        }

        if ($h{'_rt'}{'debug'}) {
            require Data::Dumper;
            print Dumper(\%h);
        }
        if (defined $h{'_FAIL'}) {
            require Data::Dumper;
            print "\n" . Dumper($h{'_FAIL'});
        }
    }
    else {
        show_usage();
    }
    print "\n";
}

################################################################################

=pod

=head1 NAME

=over 4

user_db_restore

=back

=head1 COMPANY

=over 4

Bluehost.com

=back

=head1 AUTHOR

=over 4

Ryan Neal <rneal@bluehost.com>

=back

=head1 DESCRIPTION

=over 4

Intended to provide a means of quickly finding most recent mysql dumps, and
restoring them for databases that are found to not exist.

=back

=head1 USAGE

=head4 B<-h> : help :
simple listing of (thought to be) desirable command line switches.

=head4 B<-f> : fixbackuplinks :
run the /usr/sec/bin/fixbackuplinks script before proceeding.

=head4 B<-r> : restore :
Find the most current backed up mysql dumps {daily, weekly, monthly},
compare findings against locally existing databases, and then take appropriate steps.
By default this only outputs the intended commands.

=over 4

B<-C> : COMMIT :
Actually run the commands.

=back

=head4 B<-l> : list :
Find all the backed up mysql dumps {daily, weekly, monthly} and list only the most current.

=head4 B<-L> : list all :
Find all the backed up mysql dumps {daily, weekly, monthly} and list them all.

=over 4

B<-b> : batch :
Eliminate human formatting of output.

B<-t> : timestamps :
Same as list but with prettier timestamps.

=back

=cut

################################################################################
sub eval_params($)
{
    my $href = shift;
    foreach my $p (@ARGV) {
        if ($p =~ $href->{'_rParam'}) {
            my $param = $1;

            $p =~ s/batch/b/g;
            $p =~ s/help/h/g;
            $p =~ s/time/t/g;

            $p =~ s/restore/r/g;
            $p =~ s/commit/C/g;
            $p =~ s/listall/L/g;
            $p =~ s/list/l/g;
            $p =~ s/fixbackuplinks/f/g;

            while ($param =~ s/([bCfhlLnrtdv])//) {
                if ($1 eq 'b') {
                    $href->{'_rt'}{'interactive'} = 0;
                }
                elsif ($1 eq 'C') {
                    $href->{'_rt'}{'pretend'} = 0;
                }
                elsif ($1 eq 'f') {
                    $href->{'_rt'}{'fixbackuplinks'} = 1;
                }
                elsif ($1 eq 'h') {
                    $href->{'_rt'}{'help'} = 1;
                }
                elsif ($1 eq 'l') {
                    $href->{'_rt'}{'list'} = 1;
                }
                elsif ($1 eq 'L') {
                    $href->{'_rt'}{'list'}      = 1;
                    $href->{'_rt'}{'only_last'} = 0;
                }
                elsif ($1 eq 'r') {
                    $href->{'_rt'}{'restore'} = 1;
                }
                elsif ($1 eq 't') {
                    $href->{'_rt'}{'use_epoch'} = 0;
                }
                elsif ($1 eq 'd') {
                    $href->{'_rt'}{'debug'} = 1;
                }
                elsif ($1 eq 'v') {
                    $href->{'_rt'}{'verbose'} = 1;
                }
            }
            if ($param) {
                warn "Unexpected parameter ( $param )\n" if ($href->{'_rt'}{'verbose'});
            }
        }
        else {
            if ($p =~ $href->{'_rUserDB'}) {
                $href->{'_filt'}{'db'}{$p} = 1;
                $href->{'_rt'}{'dfilt'} .= "${p},";
                $href->{'_filt'}{'cust'}{$1} = 1;
                $href->{'_rt'}{'cfilt'} .= "${1}*,";
            }
            else {
                $href->{'_filt'}{'cust'}{$p} = 1;
                $href->{'_rt'}{'cfilt'} .= "$p,";
            }
        }
    }
    $href->{'_rt'}{'cfilt'} =~ s/,$//g if (defined $href->{'_rt'}{'cfilt'});
    $href->{'_rt'}{'dfilt'} =~ s/,$//g if (defined $href->{'_rt'}{'dfilt'});
    if ((!$href->{'_rt'}{'interactive'} || !$href->{'_rt'}{'use_epoch'}) && !($href->{'_rt'}{'list'} || $href->{'_rt'}{'restore'})) {
        warn "(Assuming you're wanting a [l]ist)\n\n" if ($href->{'_rt'}{'verbose'});
        $href->{'_rt'}{'list'} = 1;
    }
}

################################################################################
sub get_backups($)
{
    my $href = shift;
    foreach my $bdir (qw(/backup)) {
        foreach my $btype (qw( daily weekly monthly )) {
            my $broot = "${bdir}/cpbackup/${btype}";
            if (opendir BROOT, $broot) {
                while (my $cust = readdir BROOT) {
                    if ($cust !~ $href->{'_rExcluded'}) {
                        my $cust_db_backdir = "${broot}/${cust}/mysql";
                        if (-d $cust_db_backdir) {
                            if (opendir CUSTDBDIR, $cust_db_backdir) {
                                while (my $cust_back = readdir CUSTDBDIR) {
                                    if ($cust_back !~ $href->{'_rExcluded'} && $cust_back =~ $href->{'_rUserDump'}) {
                                        my $db_name = $1;
                                        if ("${cust_db_backdir}/${cust_back}" =~ $href->{'_rBackupFile'}) {
                                            my @stat = stat("${cust_db_backdir}/${cust_back}");
                                            $href->{'_bak'}{$cust}{$db_name}{$btype}{'dump'}  = $1;
                                            $href->{'_bak'}{$cust}{$db_name}{$btype}{'epoch'} = $stat[9];
                                            $href->{'_bak'}{$cust}{$db_name}{$btype}{'size'}  = $stat[7];
                                            $href->{'_bak'}{$cust}{$db_name}{$btype}{'type'}  = $btype;
                                            $href->{'_bak'}{$cust}{$db_name}{$btype}{'name'}  = $db_name;
                                            if (!defined $href->{'_bak'}{$cust}{$db_name}{'last'} || $href->{'_bak'}{$cust}{$db_name}{'last'}{'epoch'} < $stat[9]) {
                                                $href->{'_bak'}{$cust}{$db_name}{'last'} = $href->{'_bak'}{$cust}{$db_name}{$btype};
                                            }
                                        }
                                        else {
                                            warn "Skipping (${cust_db_backdir}/${cust_back})\n\n" if ($href->{'_rt'}{'verbose'});
                                        }
                                    }
                                }
                            }
                            closedir CUSTDBDIR;
                        }
                        else {
                            warn "Expected to be able to open ($cust_db_backdir), but was not.\n" if ($href->{'_rt'}{'verbose'});
                        }
                    }
                }
                closedir BROOT;
            }
            else {
                warn "($broot) was expected to exist, it didn't.\n" if ($href->{'_rt'}{'verbose'});
            }
        }
    }
    foreach my $cust (keys %{ $href->{'_bak'} }) {
        foreach my $bak (keys %{ $href->{'_bak'}{$cust} }) {
            $href->{'_weight'}{$cust} += $href->{'_bak'}{$cust}{$bak}{'last'}{'size'};
            $href->{'_bak'}{$cust}{$bak}{'last'}{'type'} = $href->{'_bak'}{$cust}{$bak}{'last'}{'type'} . ' <-' if ($href->{'_rt'}{'interactive'} && !$href->{'_rt'}{'only_last'});
        }
    }
}

################################################################################
sub get_DBs($)
{
    my $href = shift;
    foreach my $line (`$href->{ '_mysql_bin' } -e 'show databases;'`) {
        if ($line !~ $href->{'_rExcludeDB'} && $line =~ $href->{'_rExistingDB'}) {
            $href->{'_db'}{$1} = 1;
        }
    }
}

################################################################################
sub list_backups($)
{
    my $href    = shift;
    my $count   = 0;
    my $pf_fmat = "%s\t%s\t%s\t%s\t%s\t%s\n";
    if ($href->{'_rt'}{'interactive'}) {
        $pf_fmat = "%-10s\t%-30s\t%-8s\t%-8s\t%-25s\t%s\n";
        print 'Filter Cust(' . $href->{'_rt'}{'cfilt'} . ")\n" if (defined $href->{'_rt'}{'cfilt'});
        print 'Filter DB(' . $href->{'_rt'}{'dfilt'} . ")\n"   if (defined $href->{'_rt'}{'dfilt'});
        print "\n";
        printf $pf_fmat, 'user', 'db', 'size', 'type', 'date', 'dump';
        printf $pf_fmat, '----------', '-----------------------------', '--------', '--------', '-------------------------', '------------------------------------------------------';
    }
    foreach my $cust (keys %{ $href->{'_bak'} }) {
        if (!defined $href->{'_rt'}{'cfilt'} || defined $href->{'_filt'}{'cust'}{$cust}) {
            foreach my $bak (keys %{ $href->{'_bak'}{$cust} }) {
                if (!defined $href->{'_rt'}{'dfilt'} || defined $href->{'_filt'}{'db'}{$bak}) {
                    my @btypes = ($href->{'_rt'}{'only_last'}) ? qw(last) : qw( daily weekly monthly );
                    foreach my $btype (@btypes) {
                        if (defined $href->{'_bak'}{$cust}{$bak}{$btype}) {
                            my $date = ($href->{'_rt'}{'use_epoch'}) ? $href->{'_bak'}{$cust}{$bak}{$btype}{'epoch'} : '' . localtime($href->{'_bak'}{$cust}{$bak}{$btype}{'epoch'}) . '';
                            printf $pf_fmat, $cust, $bak, $href->{'_bak'}{$cust}{$bak}{$btype}{'size'}, $href->{'_bak'}{$cust}{$bak}{$btype}{'type'}, $date,
                              $href->{'_bak'}{$cust}{$bak}{$btype}{'dump'};
                            $count++;
                        }
                    }
                }
            }
        }
    }
    print "\n$count\n" if ($href->{'_rt'}{'interactive'});
}

################################################################################
sub restore_DBs($)
{
    my $href              = shift;
    my $backup_count      = 0;
    my $skip_backup_count = 0;
    foreach my $cust (keys %{ $href->{'_bak'} }) {
        if (!defined $href->{'_rt'}{'cfilt'} || defined $href->{'_filt'}{'cust'}{$cust}) {
            foreach my $db (keys %{ $href->{'_bak'}{$cust} }) {
                if (!defined $href->{'_rt'}{'dfilt'} || defined $href->{'_filt'}{'db'}{$db}) {
                    $backup_count++;
                    if (!defined $href->{'_db'}{$db}) {
                        push @{ $href->{'_rstor'} }, $href->{'_bak'}{$cust}{$db}{'last'};
                    }
                    else {
                        $skip_backup_count++;
                    }
                }
            }
        }
    }
    my $restore_count = @{ $href->{'_rstor'} };
    print "\nFound:\t\t$backup_count\nSkip:\t\t$skip_backup_count\nRestore:\t$restore_count\n" if ($href->{'_rt'}{'interactive'});
    if (@{ $href->{'_rstor'} }) {
        my $i = 1;
        if ($href->{'_rt'}{'pretend'}) {
            foreach my $rstor (@{ $href->{'_rstor'} }) {
                printf "[%d/%d]\t%s\n", $i++, $restore_count, $rstor->{'name'} if ($href->{'_rt'}{'interactive'});
                print "$href->{ '_mysqladmin_bin' } create $rstor->{ 'name' }" . "\n";
                print "$href->{ '_mysql_bin' } $rstor->{ 'name' } < $rstor->{ 'dump' }" . "\n";
            }
            print "\nPretend!\n" if ($href->{'_rt'}{'interactive'});
        }
        else {
            if ($href->{'_rt'}{'interactive'}) {
                local ($|) = (1);
                print chr(7);
                print "\nYou're about to attempt writing to a live DB!\n\tPress <Enter> to continue:\n";
                my $resp = <STDIN>;
            }
            else {
                foreach my $i (1 .. 4) {
                    print "$i ";
                    print chr(7);
                    sleep 1;
                }
                print "\n";
            }
            foreach my $rstor (sort { $a->{'size'} <=> $b->{'size'} } @{ $href->{'_rstor'} }) {
                if ($href->{'_rt'}{'interactive'}) {
                    printf "[%4d/%4d] %-20s", $i++, $restore_count, $rstor->{'name'};
                }
                else {
                    print "$rstor->{'name'}\t";
                }
                chomp(my $create_db_o = `$href->{ '_mysqladmin_bin' } create $rstor->{ 'name' }`);
                if ($create_db_o eq '') {
                    chomp(my $sql_o = `$href->{'_mysql_bin' } $rstor->{ 'name' } < $rstor->{ 'dump' } 2>&1`);
                    if ($sql_o eq '') {
                        print "SUCCESS\n";
                    }
                    else {
                        print chr(7);
                        print "FAIL\n";
                        push @{ $href->{'_FAIL'} }, { 'event' => 'restore', 'dump' => $rstor->{'dump'}, 'db' => $rstor->{'name'}, 'exit' => $?, 'error' => $sql_o };
                    }
                }
                else {
                    print chr(7);
                    push @{ $href->{'_FAIL'} }, { 'event' => 'create db', 'db' => $rstor->{'name'}, 'exit' => $?, 'error' => $create_db_o };
                }
            }
        }
    }
}

################################################################################
sub show_usage()
{
    print "Usage:\nuser_db_restore [-bChflLtr] {user [user]...}\n";
    print "\t-b : batch\n";
    print "\t-C : actually do the restores (default: list actions to be taken)\n";
    print "\t-h : help\n";
    print "\t-f : run fixbackuplinks first\n";
    print "\t-l : list\n";
    print "\t-L : listall\n";
    print "\t-t : time\n";
    print "\t-r : restore\n";
}
