#! /usr/bin/env perl
use Getopt::Long;
use DBI;
use strict;
use warnings;

sub usage {
    die "usage: $0 [FLAGS] --plugin=PLUGIN [--where=WHERE]

FLAGS
  --skip-suspended
  --skip-wordfence
  --skip-backup

PLUGIN
  The plugin 'slug', as it appears in the database or wp-content/plugins path,
  or wordpress.org URL, f.e.
    themegrill-demo-importer (for ThemeGrill Demo Importer)
    wordpress-seo (for Yoast SEO)
    wpforms-lite (for Contact Form by WPForms)

WHERE
  Arbitrary SQL syntax that's injected into the query used to select
  plugins to upgrade. No care is taken to avoid SQL injections.

  The base query:
    SELECT user,db,root FROM plugins WHERE plugin='plugin'

  The query with --where=\"pver <> '3.9.4'\":
    SELECT user,db,root FROM plugins WHERE plugin='plugin' AND pver <> '3.9.4'
";
}

my $cphp = '/opt/cpanel/ea-php72/root/usr/bin/php';
my (%options, %wfence, $version);
my $now = time;
GetOptions(
    "skip-suspended" => \$options{skipsuspended},
    "skip-wordfence" => \$options{skipwordfence},
    "skip-backup" => \$options{skipbackup},
    "plugin=s" => \$options{plugin},
    "where=s" => \$options{where},
    "minor" => \$options{minor},
    "patch" => \$options{patch},
    "version=s" => \$options{version},
) or usage;
usage unless defined $options{plugin};
$options{where} = "AND $options{where}" if defined $options{where};
$options{where} = "" unless defined $options{where};
$version = "--minor" if defined $options{minor};
$version = "--patch" if defined $options{patch};
$version = "--version=$options{version}" if defined $options{version};
$version = "" unless defined $version;

my $dbh = DBI->connect("dbi:SQLite:dbname=/var/lib/eig/dc/plugins", undef, undef, { RaiseError => 1 });

if ($options{skipwordfence}) {
    %wfence = map { @$_, 1 } @{$dbh->selectall_arrayref("SELECT root FROM plugins WHERE plugin='wordfence'")};
}

for (@{$dbh->selectall_arrayref("SELECT user,db,root FROM plugins WHERE plugin='$options{plugin}' $options{where}")}) {
    my ($user, $db, $root) = @$_;
    next if $options{skipsuspended} && -f "/var/cpanel/suspended/$user";
    next if $options{skipwordfence} && exists $wfence{$root};
    chdir $root or do { warn "not able to cd to $root -- skipping upgrade"; next };
    unless ($options{skipbackup}) {
        backup($user, $db) or do {
            warn "Failed to back up $db for $root -- skipping upgrade\n";
            next;
        };
    }
    upgrade($user, $root, $options{plugin});
}

sub backupfile {
    my ($user, $db) = @_;
    my $name = "/home/$user/$db.$now.sql";
    return $name if -d "/home/$user/";
    my @pwent = getpwnam($user);
    return $name unless @pwent; # will fail to open for writing
    return $pwent[7]."/$db.$now.sql";
}

sub backup {
    my ($user, $db) = @_;
    my $name = backupfile($user, $db);
    return 1 if -f $name; # we've got a duplicate upgrade somehow
    open my $f, '>', $name or do {
        warn "Failed to open $name for writing : $!";
        return 0;
    };
    chmod 0600, $name or do {
        warn "Failed to chmod 0600 $name : $!";
        close $f;
        unlink $name;
        return 0;
    };
    open my $dump, '-|', 'mysqldump', $db or do {
        warn "Failed to mysqldump $db for $user : $!";
        close $f;
        unlink $name;
        return 0;
    };
    while (defined(my $line = <$dump>)) {
        print {$f} $line;
    }
    close $dump;
    close $f;
    print "Backup: $name\n";
    return 1
}

sub upgrade {
    my ($user, $root, $plugin) = @_;
    if ($root =~ /["\n!]/) { warn "skipping suspect docroot: $root"; next } # paranoia
    if ($plugin =~ /["\n!']/) { warn "skipping suspect plugin: $root"; next } # paranoia
    my $shell = "su - $user -s /bin/bash -c";
    my $wpcli = qq{/usr/local/bin/wp --path="$root"};
    $wpcli = "$cphp $wpcli" if -x $cphp;

    chomp(my $pre = qx{$shell "$wpcli plugin status $plugin --skip-themes --skip-plugins|grep Version:"});
    system qq{$shell "$wpcli plugin update $plugin $version --skip-themes --skip-plugins"};
    chomp(my $post = qx{$shell "$wpcli plugin status $plugin --skip-themes --skip-plugins|grep Version:"});
    print "WP-MASS-UPGRADE $user $root $pre $post\n";
}
