perl <<'EOF'
use warnings;
use strict;

use File::Which;

my $domain='domain_placeholder';
my $server='server_placeholder';

die "[!!] Mailchannels is not enabled on $server.\n"
    unless ( -f "/etc/exim_enable_mailchannels" or -f "/etc/exim_force_mailchannels" );

open my $userdomains, '<', '/etc/userdomains'
    or die "[!!] Failed to open userdomains. Is this a CPanel server?\n";
my $user;
while (my $userdomain_line = <$userdomains>) {
    chomp $userdomain_line;
    ($user) = $userdomain_line =~ m/^$domain: (\S+)$/ and last;
}
close $userdomains;

die "[!!] Failed to locate $domain on $server.\n"
    unless defined $user;

die "[!!] Domain $domain belongs to suspended user $user\n"
    if -f "/var/cpanel/suspended/$user";

my $at = which('at')
    or die "[!!] At is not installed on $server. Please escalate this.\n";

if ( -s "/etc/exim_excludesender_mailchannels" ) {
    open my $mcwhitelist, '<', '/etc/exim_excludesender_mailchannels'
        or die "[!!] Failed to open MailChannels whitelist.\n";
    while (my $mcwhitelist_line = <$mcwhitelist>) {
        chomp $mcwhitelist_line;
        $mcwhitelist_line =~ /^$domain$/
            and die "[!!] Domain $domain is already whitelisted.\n";
    }
    close $mcwhitelist;
}

open my $mcwhitelist_append, '>>', '/etc/exim_excludesender_mailchannels'
    or die "[!!] Failed to open MailChannels whitelist.\n";
print $mcwhitelist_append "$domain\n";
close $mcwhitelist_append;

print "[*] Domain $domain whitelisted for MailChannels on $server for 7 days.\n\n";

qx(echo "sed -i'' '/^$domain\$/d' /etc/exim_excludesender_mailchannels" | $at now + 7 days 2>/dev/null);
warn "[!!] Failed to schedule cleanup. Please escalate this.\n" if $!;
EOF