#!/usr/bin/perl
use warnings;
use strict;
use Data::Dumper;
use Sys::Hostname;
use YAML qw (LoadFile DumpFile);
use JSON qw ( decode_json );

use FindBin qw($Bin);
use lib "$Bin/../lib";
use lib "/opt/eig_linux/lib";
use BackupServer;

my $source = hostname;
my $threads = 3;
my $job_folder = "/var/spool/backup_migrations/";
my $bk = new BackupServer;

#Get jobs from backup master and the spool folder
my $res = $bk->call_backupmaster("backupmigration?source=$source&action=get");
my $bm_jobs = decode_json($res) or logger("Unable to decode request from BM:$res",'FATAL');
my $local_jobs;
mkdir $job_folder unless -d $job_folder;
opendir (my $dh, $job_folder);
while (my $file = readdir $dh){
    next if ($file =~ m/^\./);
    $local_jobs->{$file} = LoadFile("$job_folder/$file");
}

#Lets create jobs that backupmaster says we should have
for my $job (keys %$bm_jobs){
    if (not defined $local_jobs->{$job}){
        logger("Creating job for $job",'INFO');
        $bm_jobs->{$job}->{'failures'} = 0;
        DumpFile("$job_folder/$job",$bm_jobs->{$job});
        $local_jobs->{$job} = $bm_jobs->{$job};
    }
}

#Find out which jobs are still running.
my $active = 0;
for my $job (keys %$local_jobs){
    if (defined $local_jobs->{$job}->{'pid'}){
        if (kill 0, $local_jobs->{$job}->{'pid'}){
            logger("Found $job with an active pid",'INFO');
            $active++;
        } else {
            logger("Found $job with a dead pid",'INFO');
            delete $local_jobs->{$job}->{'pid'};
            DumpFile("$job_folder/$job",$local_jobs->{$job});
        }
    }
}

#kick off a couple threads if we can
for my $job (sort { $local_jobs->{$a}->{'failures'} <=> $local_jobs->{$b}->{'failures'} }  keys %$local_jobs){
    exit if $active >= $threads;
    next if defined $local_jobs->{$job}->{'pid'};
    next if $local_jobs->{$job}->{'failures'} >= 5;
    logger("Kicking off server_migration for $job",'INFO');
    my $pid;
    $pid = fork();
    if ($pid == 0) {
        exec("/opt/eig_linux/bin/migrate_server --userbox=$job --cron > /dev/null");
    } else {
        sleep 20;
        $active++;
    }
}

sub logger {
    my $msg = shift;
    my $level = shift;
    mkdir('/var/log/backup_migrations') unless ( -d '/var/log/backup_migrations' );
    open(my $LOG, '>>', "/var/log/backup_migrations/backup_migration_queuer.log");
    if ($level =~ m/fatal/i){
        print $LOG localtime(time) . ":FATAL: $msg\n";
        die $msg;
    } else {
        print $LOG localtime(time) . ":$level: $msg\n";
        print localtime(time) . ": $msg\n";
    }
    close($LOG);
}
