#!/usr/bin/perl
use strict;
use DBI;
use CGI;
use YAML 'LoadFile';
use JSON 'encode_json';
use Data::Dumper;

my $cgi = new CGI;
print $cgi->header();
my %var = $cgi->Vars;

validate(qw(source action));
my $config_settings = LoadFile("/var/www/conf/backup_master_config.yaml") || die "Failed to load config: $!\n";
my $dbh = DBI->connect("DBI:mysql:database=".$config_settings->{backup_db}.";host=localhost",$config_settings->{backup_user}, $config_settings->{backup_pass}) or die("couldnt connect to db $!");
my $source = get_server($var{'source'});
exit if ($ENV{REMOTE_ADDR} ne $source->{'ip'}); #OR from knox or bm?
get_all() if ($var{'action'} =~ m/get/);
validate(qw(dest cbox));
my $dest = get_server($var{'dest'});
my $cbox = get_server($var{'cbox'});
my $query = q(SELECT count(*) AS count FROM iscsimounts WHERE cboxid = ? AND bboxid = ?);
my $sth = $dbh->prepare($query);
$sth->execute($cbox->{'serverid'},$source->{'serverid'}) or die $sth->errstr;
my $mount_count  = $sth->fetchrow_hashref();
if ($mount_count->{'count'} == 0) {
    print encode_json({'error' => "No mounts found for $var{'cbox'} on $var{'source'}", 'status' => 'error'});
    exit;
}

#exit if the cbox does not have mounts on the source. At this point we have a trusted source  and we can return api data to it.
my $migration = get_migration();
create() if ($var{'action'} =~ m/create/);
return_error("No active migration found!") unless defined $migration->{'backupmigrationid'};
if ($var{'action'} =~ m/update/){
    update() && print encode_json({'status' => "success"});
    exit;
}
finalize() if ($var{'action'} =~ m/finalize/);

sub create {
    return_error("Duplicate migration found, refusing to create") if defined $migration->{'backupmigrationid'};
    my $resize = defined $var{'resize'} ? defined $var{'resize'} : 0;
    return_error("invalid resize parameter")  unless  ($resize == 0 || $resize == 1);
    my $minimumresize = defined $var{'minimumresize'} ? $var{'minimumresize'} : .2;
    return_error("invalid minimumresize paramter") unless  ($minimumresize >= 0 && $minimumresize <= 2);
    my $query = q(
        INSERT INTO backupmigrations(cboxid,sourceid,destid,resize,minimumresize,status,lastupdated)
        VALUES(?, ?, ?, ?, ?, 'queued', ? )
    );
    my $sth = $dbh->prepare($query);
    $sth->execute($cbox->{'serverid'},$source->{'serverid'},$dest->{'serverid'},$resize,$minimumresize,time);
    my $migration = get_migration();
    print encode_json({'status' => "success"});
    exit;
}
sub get_all {
    my $query = q(
        SELECT cbox.hostname AS  cbox,
        source.hostname AS source,
        dest.hostname AS dest,
        resize,minimumresize,status,error
        FROM backupmigrations
        JOIN server AS cbox ON cbox.serverid = cboxid
        JOIN server AS source ON source.serverid = sourceid
        JOIN server AS dest ON dest.serverid = destid
        WHERE status IN ('queued','running','failed')
        AND sourceid = ?
        );
    my $sth = $dbh->prepare($query);
    $sth->execute($source->{'serverid'}) or die $sth->errstr;
    my $res = $sth->fetchall_hashref('cbox');
    print encode_json($res);
    exit;
}
sub update {
    for my $key (qw(resize minimumresize status error)){
        $migration->{$key} = $var{$key} if (defined $var{$key});
    }
    my @valid_statuses = qw( completed queued failed running );
    return_error("Invalid status parameter") unless grep (/^$migration->{'status'}$/, @valid_statuses);
##Data integrity check on vars here or just at the start?
    my $query = q(
        UPDATE backupmigrations
        SET resize = ?,
        minimumresize = ?,
        status = ?,
        error = ?,
        lastupdated = ?
        WHERE backupmigrationid = ?
    );
    my $sth = $dbh->prepare($query);
    $sth->execute( $migration->{'resize'},
        $migration->{'minimumresize'},
        $migration->{'status'},
        $migration->{'error'},
        time,
        $migration->{'backupmigrationid'}
        )  or die $sth->errstr;
}
sub finalize {
    my $query = q(
        UPDATE iscsimounts
        SET bboxid = ?
        WHERE cboxid = ?
        AND bboxid = ?
        );
    my $sth = $dbh->prepare($query);
    $sth->execute($dest->{'serverid'},$cbox->{'serverid'},$source->{'serverid'}) or die $sth->errstr;
    $migration->{'status'} = 'completed';
    update();
    print encode_json({'status' => "success"});
    exit;
}
sub get_server {
    my $server_hostname = shift;
    my $query = q(
            SELECT *,INET_NTOA(newbacknetip.backnetip) AS "ip" FROM server
            JOIN newbacknetip ON server.serverid = newbacknetip.serverid
            WHERE hostname = ?
            LIMIT 1
            );
    my $sth = $dbh->prepare($query);
    $sth->execute($server_hostname) or die $sth->errstr;
    my $res = $sth->fetchrow_hashref();
    exit unless defined $res->{'serverid'};
    return $res;
}
sub get_migration {
    my $query = q(
            SELECT * FROM backupmigrations
            WHERE cboxid = ?
            AND sourceid = ?
            AND destid = ?
            AND status in ('queued','running','failed')
            LIMIT 1
            );
    my $sth = $dbh->prepare($query);
    $sth->execute($cbox->{'serverid'},$source->{'serverid'},$dest->{'serverid'}) or die $sth->errstr;
    my $res = $sth->fetchrow_hashref();
    return $res;
}
sub return_error {
    my $error = shift;
    print encode_json({'error' => $error, 'status' => 'error'});
    #We should set a response code herE?
    exit;
}
sub validate{
    my @required = @_;
    foreach my $required (@required){
        exit unless(defined($var{$required}));
        exit unless($var{$required} =~ m/^[a-z0-9-\.]+$/);
    }
    return_error("Bad action type") unless $var{'action'} =~ m/^(finalize|create|get|update|delete)$/;
}
