#!/usr/bin/perl
use warnings;
use strict;
use Data::Dumper;
use lib "/opt/eig_linux/lib";
use DR::VM;
use BackupCompute;
use File::Slurp;
use Sys::Hostname;

my $command = shift;
my $target = shift;


my @valid_commands = qw( start stop help usage update setup status failover);
usage("Bad command") unless (defined $command && grep (/^$command$/, @valid_commands));
usage("Invalid userbox") unless (defined $target && $target =~ m/([a-z0-9\.\-]+|provo|houston|all|iscsi)$/);

my %dispatch = (
    'start'     => \&start,
    'stop'      => \&stop,
    'help'      => \&usage,
    'usage'     => \&usage,
    'update'    => \&update,
    'setup'     => \&setup,
    'status'    => \&status,
    'failover'    => \&failover,
);

my $bc = new BackupCompute;
my $clients = $bc->get_clients();


if ($target =~ m/all$/) {
    foreach my $client (keys %$clients){
        $dispatch{$command}($client);
    }
} elsif ($target  =~ m/(houston|provo)$/) {
    foreach my $client (keys %$clients){
        next unless $clients->{$client}->{'dc'} =~ m/^$target$/i;
        $dispatch{$command}($client);
    }
} elsif (defined $clients->{$target} || $target eq 'iscsi') {
    $dispatch{$command}($target);
} else {
    die "Unable to find $target  as a client\n";
}

sub start {
    my $userbox = shift;
    my $drvm = new DR::VM($userbox);
    $drvm->start();
}
sub stop {
    my $userbox = shift;
    my $drvm = new DR::VM($userbox);
    $drvm->stop();
}
sub setup {
    my $userbox = shift;
    if ($userbox eq 'iscsi') {
        my $initiator_file = '/etc/iscsi/initiatorname.iscsi';
        if (! -f $initiator_file) {
            print "No initiator name set, generating a new one....\n";
            system('echo "InitiatorName=`/sbin/iscsi-iname`" > /etc/iscsi/initiatorname.iscsi');
        }
        my $initiator_string = read_file('/etc/iscsi/initiatorname.iscsi');
        $initiator_string =~ m/InitiatorName=(\S++)/ or die "Unable to find initiator name\n";
        my $initiator_name = $1;
        my $hostname = hostname;
        my $blob = $bc->call_backupmaster("drcompute?hostname=$hostname&initiator_name=$initiator_name");
    } else {
      my $drvm = new DR::VM($userbox);
      $drvm->setup();
    }
}
sub update {
    my $userbox = shift;
    my $drvm = new DR::VM($userbox);
    $drvm->update_status();
}
sub status {
    my $userbox = shift;
    my $drvm = new DR::VM($userbox);
    $drvm->status();
}
sub failover {
    my $userbox = shift;
    my $drvm = new DR::VM($userbox);
    $drvm->failover();
}
sub usage {
    my $msg = shift // "";
    my $help  = qq(
Usage:
    dr_compute_cli ACTION TARGET
    Available Actions: @valid_commands
    The target is typically the userbox hostname, but can also be all, houston, or provo
    );
    print "$help" . "\n$msg\n";
    exit;
}
