#!/usr/bin/perl
# buptime
# by Dennis Williamson - 2012-05-04
# HostGator.com - for internal use only

use strict;
use warnings;

use version; our $VERSION = qv('3.1');

use LWP::UserAgent;
use Sys::Hostname;
use IPC::Open3;
use DateTime;
use Date::Parse;
use File::Slurp;
use JSON;
use Pod::Usage;
use Encode;

$\ = "\n";

my $hostname = hostname;
my $hgbackupdir;

sub get_user {
    # We parse args manually since we only take a single positional parameter
    my $user = shift;
    
    if ( $user =~ m{\w+[.][a-zA-Z.]+}xsm ) {
        $user = get_user_from_domain($user);
    }
    
    return $user;

}

sub get_user_from_domain {
    my $domain = shift;
    my ($curdomain, $curuser, $user);

    open(my $fh, '<', '/etc/userdomains') or die "[X] Failed to open user domains file: $!\n";
    while (<$fh>) {
        ($curdomain, $curuser) = split(/:\s+/xsm, $_);
        if ($curdomain eq $domain) {
            $user = $curuser;
            last;
        }
    }

    close($fh) or warn "[!] Failed to close user domains file: $!\n";
    
    if (!$user) {
        print '[X] Failed to find user for domain ' . $domain;
        exit 1;
    }

    return $user;
}

sub get_nas_assignment {
    my $url = shift;
    my $HTTP_STATUS_OK = 200;
    my $ua = LWP::UserAgent->new;
    my $response = $ua->get($url);
    
    if ( $response->{'_rc'} != $HTTP_STATUS_OK ) {
        print "[X] ERROR: unable to retrieve NAS assignment from $url";
        exit 1;
    } else {
        return $response->{'_content'};
    }
}

sub get_nas {
    my $url = 'http://nas.hostgator.com/assign.php?fullquery=' . $hostname;
    my $content = get_nas_assignment($url);
    my ($nas, $drive, $nas_name, $priv_ip, $part_used) = split(/\n/xsm, $content);

    if (not $nas) {print "[X] This server is not assigned to a NAS"; exit 1}
   
    return ($nas, $drive, $nas_name, $priv_ip, $part_used);
}

sub check_cron {
    my $ctype;
    open(my $fh, '<', '/var/spool/cron/root') or die "[X] Failed to open root's crontab file: $!\n";
    while (<$fh>) {
        if ($_ =~ m{(?<=backup[.]pl\s--)(.+)}xsm) {
            if ($1 ne 'innodb') {
                $ctype = $1;
                chomp($ctype);
                last;
            }
        }
    }
    close($fh) or warn "[!] Failed to close crontab file: $!\n";
    return $ctype;
}

sub run_cmd {
    my ($command, @args) = @_;
    my ($stdin, $stdout, $stderr);
    use Symbol 'gensym'; $stderr = gensym;
    my $pid = open3($stdin, $stdout, $stderr, $command, @args) or die "[X] Command $command failed\n";
    waitpid($pid, 0);

    my @output = <$stdout>;
    chomp(@output);

    return @output;
}

sub user_nas_check {
    my ($user_dir, $nas, $drive) = @_;
    my $command = '/usr/bin/ssh';
    my @args = ('-n', '-T', '-i', 
                "$hgbackupdir/backupkey",
                "root\@$nas",
                "[[ -d $drive/$hostname/$user_dir ]] && echo exists || echo does\ NOT\ exist"
        );
    
    my @output = run_cmd($command, @args);
    
    return $output[0];

}

sub read_status {
    my $file = shift;
    my $data;
    if (-e $file) {
        # use utf8 encode because some boxes auto-use JSON::PP (ones that use JSON::XS
        # don't seem to need the encode, but work fine with it)
        $data = decode_json encode('utf8', read_file($file));
    }
    
    return $data;
    
}

sub check_dirs {
    my ($user, $user_dir) = @_;
    if (! -d $user_dir) {
        # this should have already been caught in main()
        print 'Home directory for USER ' . $user . 'NOT FOUND on ' . $hostname;
        exit 1;
    } elsif (! -d "$user_dir/.cpanel") {
        print $user . 'has never logged into cPanel';
        exit 1;
    } elsif (! -f "$user_dir/.cpanel/backup_status") {
        print 'No backup_status file found for ' . $user;
        exit 1;
    }

    return;
}

sub user_check {
    my $last_date;
    my ($user, $user_dir) = @_;
    check_dirs($user, $user_dir);

    my $data = read_status("$user_dir/.cpanel/backup_status");

    if ($data->{reason} =~ m{\w+}xsm) {
        print '  Backup for USER ' . $user . ' FAILED or SKIPPED for reason: ' . $data->{reason};
        if ($data->{last}) {
            $last_date = format_time($data->{last});
        } else {
            $last_date = 'not available';
        }
        if (exists $ENV{RUSER}) {
            print "  Last attempted (NON-SKIPPED) backup for USER $user: $last_date";
        }
    } else {
        if ($data->{status} eq 'running') {
            print '  Backups CURRENTLY RUNNING for USER ' . $user;

        } else {
            print '  Backups for USER ' . $user . ' COMPLETED at ' . format_time($data->{stop});
        }

    }
}

sub full_server {
    my ($nas, $drive) = @_;
    my $type = check_cron();
    my $command = '/usr/bin/ssh';
    my @args = ('-n', '-T', '-i', "$hgbackupdir/backupkey", "root\@$nas");
    my $start_string = q{printf '%s\n' } . qq{${drive}/${hostname}.stoptime};
    my $end_string = q{ | sort -g | tail -n1 | xargs stat -c %y};

    if (!$type) {
        print "Failed to detect backup type. Please contact a backup admin\n";
        exit 1;
    }
    
    if ($type eq 'filesys') {
        push(@args, $start_string . q{.filesys.[0-9]*} . $end_string);

    } elsif ($type eq 'full') {
        push(@args, $start_string . q{.[0-9]*} . $end_string . q{; } . $start_string . q{.innodb.[0-9]*} . $end_string);

    } else {
        print "Failed to detect backup type. Please contact a backup admin\n";
        exit 1;
    }

    my @output = run_cmd($command, @args);
    my %results;

    $results{'Full'} = $output[0];
    
    if ($output[1]) {
        $results{'Innodb'} = $output[1];
    }

    return \%results;

}

sub create_dt_object {
    my $timestamp = shift;
    my $time;

    if ($timestamp =~ m{^\d+$}xsm) {
        $time = $timestamp;
    } else {
        $time = str2time($timestamp);
    }

    my $dt = DateTime->from_epoch( epoch => $time, time_zone => $ENV{'TZ'} || "America/Chicago" );
    return $dt;
}

sub format_time {
    my $timestamp = shift;
    my $dt = create_dt_object($timestamp);
    
    return $dt->strftime('%a %b %e %H:%M:%S %Z %Y');
}

sub main {
    my $user;
    my $douser = 0;
    my $current_type = 'unknown';

    if ($#ARGV > 0) { # only use 1 argument
        warn "[!] Warning: extra arguments ignored\n";
    }
    if ($ARGV[0]) {
        if (grep {$_ eq $ARGV[0]} qw{--help -h -? --man --doc}) {$\ = ''; pod2usage(-verbose => 99);}
        chomp($user = get_user($ARGV[0]));
        $douser = 1;
    }

    if (-d '/admin/hgbackupdir') {
        $hgbackupdir = '/admin/hgbackupdir';
    } else {
        $hgbackupdir = '/home/hgbackupdir';
    }

    my ($nas, $drive, $nas_name, $priv_ip, $part_used) = get_nas();
    my $result_ref = full_server($nas, $drive);

    print "\n============ SERVER info ========================\n";
    print 'Overall SERVER: ' . $hostname . "\n";
    print '  NAS: ' . $nas_name . ' (' . $nas . ')';
    print '  Backup directory on NAS: ' . $drive;
    print "  NAS partition is $part_used% full\n";

    if (-e "$hgbackupdir/.backup_running") {
        open(my $fh, '<', "$hgbackupdir/.backup_running") or die "unable to open $hgbackupdir/.backup_running\n";
        while (my $line = <$fh>) {
           ($current_type) = split(/\|/, $line);
        }
        print "  SERVER appears to be CURRENTLY backing up: $current_type\n";
        print '  Most recent:';
    }
    for my $type (keys %{$result_ref}) {
        if (defined $result_ref->{$type}) {
            print '  SERVER ' . $type . q{ Backup: } . format_time($result_ref->{$type});
        } else {
            print '  SERVER has never been backed up for type ' . $type;
        }
    }
    print "\n=================================================";

    if ($douser) {
        print "\n************  USER info  ************************";
        print "\nBackup for USER: " . $user . "\n";
        my $user_dir = (getpwnam($user))[7] or warn "[!] Warning: user not found\n";
        if ($user_dir) {
            print q{  USER's home directory is } . $user_dir;
            print q{  USER's home directory } . user_nas_check($user_dir, $nas, $drive) . " on the NAS box\n";
            user_check($user, $user_dir);
        } else {
            print q{  USER's home directory is NOT FOUND on } . $hostname;
        }
        print "\n*************************************************"
    } else {
        print "\nYou can supply a user/domain to buptime\n";
        print "usage: $0 [user]|[domain]";
    }

    exit;
}

main();

__END__

=head1 NAME

 buptime - Show backup status for the server and optionally for a user or 
           domain

=head1 DESCRIPTION

 This script will display server backup times. Optionally, it will also 
 display the backup information for a user or domain.

=head1 SYNOPSIS

 buptime [username|domain]

=head1 OPTIONS

 -?, --help          Show this message

=cut
