#!/usr/bin/perl -w

use strict;
use Data::Dumper;
use Carp;
use Sys::Hostname;

my $script = {
    name => 'Should I Migrate?',
    desc => 'Script to suggest whether or not you should migrate a new account to a given server',
    version => '0.1.0',
    author => 'Grayson Paynter',
    report => 'gpaynter@hostgator.com',
};

#### LIMITS ####
my $var_inodes_limit = 90;
my $home_inodes_limit = 93;
my $var_disk_limit = 90;
my $home_disk_limit = 93;
################

my $ok_to_migrate = 1;
my @warnings = ();

main();
sub main {
    _print_header();
    my ($hostname,$ip) = _get_basic_system_info();
    my ($numcpus) = _get_cpu_info();
    my ($sys_uptime,$apache_uptime,$mysql_uptime) = _get_uptimes();
    my ($loadavg1,$loadavg5,$loadavg15) = _get_loadavg($numcpus);
    my ($totalmem,$freemem) = _get_mem();
    _get_disk_stats();
    _get_inode_count();
    _get_iowait_and_idle();
    my (@ssh) = _get_ssh_sessions();
    my (@screens) = _get_screen_sessions();
    _get_raid_stats();
    _final_tally(@warnings);
    _end();
}

sub _print_header {
    # Print out the header information
    print "\n\033[1m" . $script->{name} . " \033[0m- " . $script->{desc} . "\n";
    print "\033[1mVersion:\033[0m " . $script->{version} . " - \033[1mAuthor:\033[0m " . $script->{author} . "\n";
    print "Report bugs to <\033[1m" . $script->{report} . "\033[0m>\n";
    print "\033[1m--------------------------------------\033[0m\n";
}

sub _get_basic_system_info {
    my $hostname = hostname || `uname -n`;
    _print_line("Hostname: $hostname");

    my $ip = `hostname -i`;
    chomp $ip;
    _print_line("Primary IP: $ip");
    return ($hostname,$ip);
}

sub _get_cpu_info {
    my $numcpus = `grep -c proc /proc/cpuinfo`;
    chomp $numcpus;
    
    if (!$numcpus) {
        croak "Unable to determine the number of CPUs!";
    }

    if ($numcpus <= 8) {
        my $msg = "Low number of CPUs: $numcpus";
        push(@warnings,$msg);
    } else {
        _print_line("CPUs: $numcpus");
    }
    return $numcpus;
}

sub _print_line {
    my ($line) = @_;
    print "\033[1m[*]\033[0m " . $line . "\n";
    }

    sub _alert {
    my ($line) = @_;
    print "\033[1m[!]\033[0m " . $line . "\n";
}

sub _get_uptimes {

    my @sys_uptime;

    open(my $UPTIME,'/proc/uptime') or croak "unable to open /proc/uptime";
    while (<$UPTIME>) {
        @sys_uptime = split(/ /,$_);
    }
    close($UPTIME);

    chomp(@sys_uptime);
    my $seconds_up = int($sys_uptime[0]);
    my $now = time;
    my $then = $now - $seconds_up;
    my $date = localtime($then);

    my $uptime = sprintf "%d days, %d hours, %d minutes and %d seconds", (gmtime $seconds_up)[7,2,1,0];
    _print_line("System Uptime: $uptime");
    _print_line("Last restart: $date");

    my $cmd = "service httpd status 2> /dev/null| grep -Po 'Server uptime:.+\$'";
    my $apache_uptime = `$cmd`;
    chomp $apache_uptime;
    _print_line("Apache Uptime: $apache_uptime");

    my $mysql_uptime = `mysqladmin status 2> /dev/null | awk '{print \$2}'`;
    _print_line("Mysql Uptime: $mysql_uptime");

    return ($seconds_up,$apache_uptime,$mysql_uptime);
}

sub _get_loadavg {
    my ($numcpus) = @_;

    my @loadavg;
    open(my $LOADAVG,"/proc/loadavg") or croak "unable to open /proc/loadavg";
    while(<$LOADAVG>) {
        @loadavg = split(/ /,$_);
    }
    close($LOADAVG);

    my $loadavg1 = $loadavg[0];
    my $loadavg5 = $loadavg[1];
    my $loadavg15 = $loadavg[2];

    my $maxload = $numcpus * 1.5;

    if ($loadavg1 > $maxload || $loadavg5 > $maxload || $loadavg15 > $maxload ) {
        my $msg = "High LoadAvg: $loadavg1 $loadavg5 $loadavg15";
        push(@warnings,$msg);
    } else {
        _print_line("LoadAvg: $loadavg1 $loadavg5 $loadavg15");
    }


    return ($loadavg1,$loadavg5,$loadavg15);
}

sub _get_mem {
    my ($totalmem,$freemem,$cached,$swapTotal,$swapFree);

    print "\n";
    _print_line("\033[1;34mMemory Stats\033[m");

    open(my $MEMINFO,"/proc/meminfo") or croak "Unable to open /proc/meminfo !";
    while (<$MEMINFO>) {
        chomp;
        if (/^MemTotal:\s+(\d+) kB$/) {
            $totalmem = $1;
            _print_line($_);
        } elsif (/^MemFree:\s+(\d+) kB$/) {
            $freemem = $1;
            _print_line($_);
        } elsif (/^Cached:\s+(\d+) kB$/) {
            $cached = $1;
            _print_line($_);
        } elsif (/^SwapTotal:\s+(\d+) kB$/) {
            $swapTotal = $1;
            _print_line($_);
        } elsif (/^SwapFree:\s+(\d+) kB$/) {
            $swapFree = $1;
            _print_line($_);
        }
    }
    close($MEMINFO);

    if ($totalmem < 16000000) {
        my $msg = "Total memory is < 16GB! ($totalmem)";
        push(@warnings,$msg);
    }

    if ($cached < 1000000) {
        my $msg = "Less than 1GB cached memory!";
        push(@warnings,$msg);
    }

    if ($freemem < 1000000 && $cached < 2000000) {
        my $msg = "Less than 1GB free memory with less than 2GB cached! ($freemem/$cached)";
        push(@warnings,$msg);
    }

    if ($swapFree < 1000000) {
   	my $msg = "Swap space is filling up! <1GB free! ($swapFree)";
        push(@warnings,$msg);
    }
    
    return ($totalmem,$freemem);
}

sub _get_disk_stats {
    my $var;
    my $homes = {};

    print "\n";
    _print_line("\033[1;34mDisk Stats\033[m");
    my @df = split(/^/,`df -h`);
    chomp @df;
    foreach my $item (@df) {
        if($item =~ /^.*(\d+)%\s+\/var$/) {
            $var = $1;
            _print_line($item);
        } elsif ($item =~ /^.+\s+(\d+)%\s+\/(home(?:|\d+))$/) {
            $homes->{$2} = $1; 
            _print_line($item);
        }
    }

    if ($var && $var > $var_disk_limit) {
        my $msg = "/var is > $var_disk_limit% full!";
        push(@warnings,$msg);
    }

    foreach my $dir (keys(%$homes)) {
        if ($homes->{$dir} > $home_disk_limit) {
            my $msg = "$homes->{dir} is > $home_disk_limit% full!";
            push(@warnings,$msg);
        }
    }
}

sub _get_inode_count {
    my $var;
    my $homes = {};

    _print_line("Inodes");
    my @df = split(/^/,`df -hi`);
    chomp @df;
    foreach my $item (@df) {
        if($item =~ /^.*(\d+)%\s+\/var$/) {
            $var = $1;
            _print_line($item);
        } elsif ($item =~ /^.+\s+(\d+)%\s+\/(home(?:|\d+))$/) {
            $homes->{$2} = $1; 
            _print_line($item);
        }
    }

    if ($var && $var > $var_inodes_limit) {
        my $msg = "/var Inodes are > $var_inodes_limit% !";
        push(@warnings,$msg);
    }

    foreach my $dir (keys(%$homes)) {
        if ($homes->{$dir} > $home_inodes_limit) {
            my $msg = "$homes->{dir} inodes are > $home_inodes_limit%";
            push(@warnings,$msg);
        }
    }

}
sub _get_iowait_and_idle {
    my $cmd = "sar | tail  -1 | awk '{print \$6,\$8}'";
    my ($iowait, $idle) = split(/ /,`$cmd`);
    
    chomp ($iowait,$idle);

    _print_line("\%IOwait: $iowait");
    _print_line("\%Idle: $idle");

    if ($iowait > 15) {
        my $msg = "\%IOwait is > 15% ($iowait%)";
        push(@warnings,$msg);
    }

    if ($idle < 10) { 
        my $msg = "\%Idle time is < 15% ($idle%)";
        push(@warnings,$msg);
    }
}

sub _get_ssh_sessions {

    print "\n";

    my $cmd = "who | awk \'{print \$1,\$2,\$5}\'";
    my @ssh = split(/^/,`$cmd`);

    chomp(@ssh);

    my $numssh = @ssh;

    _print_line("\033[1;34mSSH Sessions:\033[m ($numssh)");

    if ($numssh < 10) {
        foreach my $line (@ssh) {
            my @each = split(/ /,$line);
            my $out = sprintf("%-15s %-10s %-15s",$each[0],$each[1],$each[2]);
            _print_line($out);
        }
    } else {
        _print_line("More than 10 SSH connections...truncating");
        my $i = 0;
        while ($i < 10) {
            my $line = $ssh[$i];
            my @each = split(/ /,$line);
            my $out = sprintf("%-15s %-10s %-15s",$each[0],$each[1],$each[2]);
            _print_line($out);
            $i++;
        }
    }

    if ($numssh > 5) {
        my $msg = "More than 5 SSH sessions open! ($numssh)";
        push (@warnings,$msg);
    }

    return @ssh;
}

sub _get_screen_sessions {
    print "\n";

    my $cmd = "screen -ls";
    my @lines = split(/^/,`$cmd`);

    chomp(@lines);

    my @screens;
    foreach my $line (@lines) {
        if ($line =~ /^\s+(\d+\..*\s+\(\w+\))$/) {
            push(@screens,$1)
        }
    }
    chomp(@screens);
    my $numscreens = @screens;

    _print_line("\033[1;34mScreen Sessions:\033[m ($numscreens)");


    if ($numscreens < 10) {
        foreach my $line (@screens) {
            _print_line($line);
        }
    } else {
        _print_line("More than 10 SSH connections...truncating");
        my $i = 0;
        while ($i < 10) {
            my $line = $screens[$i];
            _print_line($line);
            $i++;
        }
    }

    if ($numscreens > 4) {
        my $msg = "More than 4 Screen sessions open! ($numscreens)";
        push (@warnings,$msg);
    }
    return @screens;
}


sub _get_raid_stats {

    print "\n";
    _print_line("\033[1;34mRAID:\033[m");
    my $megaraid = `lspci | grep MegaRAID`;

    if ($megaraid) {
        my @raidstats = split(/^/,`/opt/zabbix/sbin/raidcheck/bin/megasasctl -vvvvv`);
        chomp @raidstats;
        foreach my $line (@raidstats) {
            _print_line($line);
        }

        my $problems = `/opt/megactl/megasasctl -H -B`;
        chomp $problems;

        if ($problems) {
            my $msg = "Raid Problems: $problems";
            push(@warnings,$msg);
        }

    } else {
        _alert("Unable to get RAID stats!")
    }
}

sub _final_tally {
    my (@warnings) = @_;
    my $numwarnings = @warnings;
    # Essentially, we want to know if we're OK to migrate to this box
    # If we have 1 or more total warnings, recommend NOT migrating to this box
    if ($numwarnings > 0) {
        print "\n";
        _alert("\033[1;31m$numwarnings warnings found!\033[m");
        foreach my $item (@warnings) {
            _alert($item);
        }
        print "\n";
        _alert("\033[1;31mPlease do not migrate any new accounts to this server without first consulting a Supervisor!\033[m");

    } elsif ($ok_to_migrate) {
    # Else: Should be OK to migrate here
        print "\n";
        _print_line("\033[1;32m0 warnings, you should be OK to migrate a new account to this server.\033[m");
    } else {
        print Dumper "wat";
    }
}

sub _end {
    _print_line("End.");
}

