#!/usr/local/cpanel/3rdparty/bin/perl

use strict;
use warnings;

our $VERSION = '1.152380';

use feature 'state';

use version;

use Symbol 'gensym';
use POSIX ':sys_wait_h';
use File::Copy qw(move);
use Time::HiRes qw(sleep);
use English qw( -no_match_vars );
use IPC::Open3 ();
use Getopt::Long::Descriptive;
use IO::Prompt ();
use Log::Log4perl ();

use Cpanel::Version ();
use Cpanel::FileUtils ();
use Cpanel::SysQuota ();

use lib '/opt/hgmods/monitoring/lib';
use HG::Monitoring::Server ();
use HG::Monitoring::User ();

# Disable output buffering
$OUTPUT_AUTOFLUSH = 1;

# Define logging confiuration
my $logging_config = \q(
    ###################################################################
    log4perl.rootLogger=DEBUG, ROOTLOG, ROOTSCREEN
    #------------------------------------------------------------------
    log4perl.appender.ROOTLOG=Log::Log4perl::Appender::File
    log4perl.appender.ROOTLOG.filename = /opt/hgmods/monitoring/logs/suspbakup.log
    log4perl.appender.ROOTLOG.layout=PatternLayout
    log4perl.appender.ROOTLOG.layout.ConversionPattern = %d - %-5p - %c - %m%n
    #------------------------------------------------------------------
    log4perl.appender.ROOTSCREEN = Log::Log4perl::Appender::ScreenColoredLevels
    log4perl.appender.ROOTSCREEN.color.WARN = bold yellow
    log4perl.appender.ROOTSCREEN.color.ERROR = bold red
    log4perl.appender.ROOTSCREEN.layout = PatternLayout
    log4perl.appender.ROOTSCREEN.layout.ConversionPattern = [%-5p] %m%n
    log4perl.appender.ROOTSCREEN.Threshold = DEBUG
);

# Initialize logger object
Log::Log4perl->init($logging_config);

# Obtain a reference to the logger object
my $logger = Log::Log4perl::get_logger($VERSION);

# Create a new server object
my $server = HG::Monitoring::Server->new;

# Parse command line options
my ( $opt, $usage ) = describe_options(
    '%c %o <path>',
    [ 'ticket|t=s',  "ticket number associated with this backup",
        { callbacks => { 'ticket number validation' => \&ticket_isvalid } }
    ],
    [ 'noatd|n', "don't add a task to remove the download link"],
    [ 'skiplimit|l', "perform backup even if account exceeds the 20G hard limit"],
    [ 'force|f', "force overwrite of any existing packages"     ],
    [ 'skiphomedir|s', "don't include the user's home directory in the created backup" ],
    [ 'reseller|r', "perform operation on whole reseller"               ],
    [ 'version|v',  "print version and exit"                            ],
    [ 'help|h',     "print usage message and exit"                              ],
);

# Get username from the command line used
my $provided_user = shift;

# Output server information.
print $server->banner;

# Verify that a valid username has been supplied
if ( ! user_isvalid($provided_user) ) { print($usage->text), exit(1) }


if ( $opt->version ) { printf("%s Version: %s\n", $0, $VERSION), exit }
if ( $opt->help ) { print($usage->text), exit }

my ( @userlist, @download_urls, @symlink_locations, @errors );
push(@userlist, $opt->reseller ? HG::Monitoring::User->new->get_cpanel_accounts($provided_user) : $provided_user);

foreach my $user ( @userlist ) {
    state ( $htaccess_created );
    # Set final package file name
    my $package_file = "cpmove-$user.tar.gz";

    # Verify that a valid username has been supplied
    if ( ! user_isvalid($user) ) { next }

    # Get home directory location.
    my $home = get_user_home_dir($user) || next;

    # Prompt for ticket number if not already specified and sanity check ticket number.
    $opt->{ticket} = validate_ticket($opt->ticket);

    # Get disk usage for $user's home directory.
    if ( ! $opt->skiplimit && ! user_size_isvalid($user) ) { next }

    # Begin the pkgacct for $user
    if ( ! pkgacct($user) ) {
        my $error = "Failed to properly create account package for '$user'";
        push @errors, "FATAL: " . $error;
        $logger->fatal($error);
        next;
    }

    if ( ! -f "$home/$package_file" ) {
        my $error = "'$home/$package_file' not found after account backup.";
        push @errors, "FATAL: " . $error;
        $logger->fatal($error);
        next;
    }

    if ( ! chmod 0644, "$home/$package_file" ) {
        my $error = "Failed to modify file permissions for '$home/$package_file'";
        push @errors, "ERROR: " . $error;
        $logger->error($error);
    }

    my $package_size = ( -s "$home/$package_file" ) / ( 1024**2 );
    my $dl_dir = sprintf("/usr/local/apache/htdocs/%s", $opt->ticket);

    if ( ! -d $dl_dir && ! mkdir $dl_dir ) {
        my $error = "Failed to create directory '$dl_dir'";
        push @errors, "ERROR: " . $error;
        $logger->error($error);
    }

    my $htaccess_loc = "$dl_dir/.htaccess";

    if ( ! -e $htaccess_loc ) {
        if ( open my $htaccess_fh, '>', $htaccess_loc ) {
            print $htaccess_fh "RewriteEngine off\n";
            print $htaccess_fh "Options +FollowSymLinks\n";
            close $htaccess_fh;
            $htaccess_created = 1;
        } else {
            my $error = "Unable to open '$htaccess_loc' for writing: $ERRNO";
            push @errors, "ERROR: " . $error;
            $logger->error($error);
        }
    } elsif ( ! $opt->reseller || ! $htaccess_created ) {
        my $error = "'$htaccess_loc' already exists.";
        push @errors, "WARNING: " . $error;
        $logger->warn($error);
    }

    if ( -e "$dl_dir/$package_file" ) {
        my $error = "There is already a file located at '$dl_dir/$package_file'";
        push @errors, "WARNING: " . $error;
        $logger->warn($error);
    } elsif ( ! symlink( "$home/$package_file", "$dl_dir/$package_file" ) ) {
        my $error = "Unable to create symlink: $dl_dir/$package_file -> $home/$package_file";
        push @errors, "WARNING: " . $error;
        $logger->warn($error);
    } else {
        push @symlink_locations, "$dl_dir/$package_file";
    }

    # my ( undef, undef, $uid, $gid ) = getpwnam("nobody");
    # chown( $uid, $gid, "/$home/$user/cpmove-$user.tar.gz" );
    # chown( $uid, $gid, "/usr/local/apache/htdocs/$ID" );
    # system("chown -h nobody. /usr/local/apache/htdocs/$ID/cpmove-$user.tar.gz");

    my $download_url = sprintf("http://%s/%s/%s", $server->{info}->{hostname}, $opt->ticket, $package_file);

    push @download_urls, $download_url . sprintf(" ( %-.2fM )", $package_size);

    $logger->info(sprintf "Download available at: %s", $download_url);
    $logger->info(sprintf "File is %-.2fM in size.", $package_size);

}

if ( $opt->skiphomedir ) {
    push @errors, "WARNING: --skiphomedir used!  Backup does not include the user's home directory.";
}

unless ( $opt->noatd ) {
    foreach my $symlink ( @symlink_locations ) {
        if ( system("echo rm -f '$symlink' | at now + 72 hours") != 0 ) {
            my $error = " already exists.";
            push @errors, "ERROR: " . $error;
            $logger->warn($error);
        }
    }
}

if ( @errors ) {
    my $error_list = join("\n", @errors);
    print "\n*******************************************************************\n";
    print "  WARNING WARNING WARNING WARNING WARNING WARNING WARNING WARNING  \n";
    print "*******************************************************************\n\n";
    print "The following errors or warnings were encountered:\n\n";
    print $error_list;
    print "\n\n*******************************************************************\n";
    print "  WARNING WARNING WARNING WARNING WARNING WARNING WARNING WARNING  \n";
    print "*******************************************************************\n\n";
}

if ( @download_urls ) {
    print "\nDone! Copy and paste the response below,\n\n";
    print "===================================================\n\n";

    if ( @download_urls > 1 ) {
        printf("I have created backups of your accounts which you may download%s via the following URLs:\n\n", $opt->noatd ? '' : ', for the next 72 hours,');
    } else {
        printf("I have created a backup of your account which you may download%s via the following URL:\n\n", $opt->noatd ? '' : ', for the next 72 hours,');
    }

    printf("%s\n", join("\n", @download_urls));
    printf("\nPlease let us know if you are unable to download %s for any reason so we may further assist you.\n\n", @download_urls > 1 ? 'these backups' : 'this backup');
    print "===================================================\n\n";
}

unless ( $opt->noatd ) {
    print "Add the following to the ticket notes:\n\n";
    print "===================================================\n\n";
    printf("The following symlink%s will be removed 72 hours from now:\n\n", @symlink_locations > 1 ? 's' : '');
    printf("%s\n", join("\n", @symlink_locations));
    print "\n===================================================\n\n";
}

sub pkgacct {
    my $user = shift;
    my @cmd = qw( /scripts/pkgacct );
    my($wtr, $rdr, $err);

    if ( $opt->skiphomedir ) {
        push @cmd, '--skiphomedir';
    }

    push @cmd, $user, get_user_home_mount($user);

    # Set final package file name
    my $package_file = "cpmove-$user.tar.gz";

    my $src = get_user_home_mount($user) . "/$package_file";
    my $dst = get_user_home_dir($user) . "/$package_file";

    if ( -f $dst ) {
        $logger->warn("Existing package file located at: $dst");

        if ( $opt->force ) {
            $logger->info("Force overwrite requested.");
        } else {
            my $answer = IO::Prompt::prompt( "Use existing package? ", "-tty", "-newline" => "", "-yes_no" );
            if ( $answer ) {
                return $dst;
            } else {
                $logger->warn("Skipping package creation for $user");
                return;
            }
        }
    }

    $err = gensym();

    # Check cPanel version to see if it is newer than the last version we patched
    cp_ispatched() ? skip_limits($user) : push @cmd, '--skip-limit';

    # $logger->info("Beginning backup generation.");
    $logger->info("Generating backups.");
    my $pid = IPC::Open3::open3( $wtr, $rdr, $err, @cmd );

    if ( ! $pid ) {
        $logger->fatal("Unable to run pkgacct.");
        return;
    }

    # Wait for pkgacct to terminate
    while ( 1 ) {
        my $res = waitpid($pid, WNOHANG);
        if ( $res == -1 ) {
            my $child_exit_status = $? >> 8;
            $logger->error("An error occured: $child_exit_status");
            return;
        }
        last if ( $res );

        swirl();
        sleep(0.1);
    }
    print "\r";

    close $wtr;
    chomp(my @pkgout = <$rdr>);
    chomp(my @pkgerr = <$err>);
    close $rdr;
    close $err;

    foreach my $error ( @pkgerr ) {
        next if ( $error =~ m/^\s*$/xms );
        next if ( $error =~ m/\/MYSQL_DATA\//xms );
        $logger->warn($error);
    }

    my @stdouterr = grep {/error|failed|permission/i} @pkgout;

    if ( @stdouterr ) {
        print "Also, the following potential errors occured during backup creation. Manually confirm that they are real issues:\n";
        print "@stdouterr \n";
    }

    if ( ! move($src, $dst) ) {
        $logger->error("Unable to move '$src' to '$dst'");
        return;
    }

    return $dst;
}

sub swirl {
    # Create Pretty Motion
    my @motion = ( '|', '/', '-', '\\' );
    state $motionchar = 0;

    printf("\r%s\r", ' ' x 15);

    if ( $motionchar < scalar @motion ) {
        printf("Working: %s  ", $motion[$motionchar++]);
    } else {
        $motionchar = 0;
        swirl();
    }
}

sub get_user_home_mount {
    my $user = shift || return;
    my $home = get_user_home_dir($user);

    if ( ! $home ) {
        $logger->error("Unable to determine the home directory for '$user'.");
    }

    if ( defined $home && length $home ) {
        my @c_dir_arry = split('/', $home);
        pop @c_dir_arry;
        return join('/', @c_dir_arry);
    }

    return;
}

sub get_user_home_dir {
    my $user = shift || return;

    my $home = (getpwnam $user)[7];
    if ( ! defined $home || ! length $home ) {
        $logger->fatal("Unable to determine the home directory for '$user'.");
        return;
    }

    return $home;
}

sub user_size_isvalid {
    my $user = shift || return;
    my $limit     = 4194304 * 1024;
    my $hardlimit = 20971520 * 1024;

    state $usagemap;


    if ( ! defined $usagemap || ! $usagemap->{users}->{$user} ) {
        my $mountpoint = get_user_home_mount($user);
        my $current_usagemap = load_usage($mountpoint);
        foreach my $key ( %{$current_usagemap} ) {
            $usagemap->{$key} = $current_usagemap->{$key};
        }
    }

    my $found;
    my $diskuse = $usagemap->{users}->{$user}->{space};

    if ( defined $diskuse && $diskuse =~ /^[0-9]+$/ ) { $found = 1 }

    if ( ! $found ) {
        my $home = get_user_home_dir($user) || return;
        $logger->warn("Diskusage not defined by quota or quotas not used, running du instead.");

        my ( $wtr, $rdr, $err );
        $err = gensym();
        my $pid = IPC::Open3::open3( $wtr, $rdr, $err, qq(du -s $home) );

        if ( ! $pid ) {
            $logger->error("Unable to invoke du: $ERRNO");
            return;
        }

        # Wait for du to terminate
        while ( 1 ) {
            my $res = waitpid($pid, WNOHANG);
            if ( $res == -1 ) {
                my $child_exit_status = $? >> 8;
                $logger->error("An error occured invoking du: $child_exit_status");
            }
            last if ( $res );

            swirl();
            sleep(0.1);
        }
        print "\r";

        close $wtr;
        my @du_out = <$rdr>;
        my @du_err = <$err>;
        close $rdr;
        close $err;

        if ( $du_out[0] =~ /^([0-9]+)\s+\S+$/ ) {
            $found = 1;
            $diskuse = $1;
            $usagemap->{users}->{$user}->{space} = $diskuse;
            $logger->info(sprintf("Diskage for '%s' is: %-.2fM", $user, $diskuse / (1024**2)));
        }
    } else {
        $logger->info(sprintf("quota check of '%s' succeeded as: %-.2fM", $user, $diskuse / (1024**2)));
    }

    if ( ! $found ) {
        $logger->error("Unable to determine disk usage for '$user'.");
    }

    if ( defined $diskuse ) {
        if ( $diskuse > $hardlimit ) {
            $diskuse = int $diskuse / (1024**2);
            $logger->fatal("Account '$user' is over 20G in size. Current usage is $diskuse MB. Backup must be created manually.");
            return;
        } elsif ( $diskuse > $limit ) {
            $diskuse = int $diskuse / (1024**2);
            $logger->warn("Account '$user' is over 4G in size. Current usage is $diskuse MB.");
        }
        return 1;
    }

    return;
}

sub load_usage {
    my $disk = shift;
    return unless defined $disk;

    my %report;
    my $user2reseller = load_resellers();

    my $quotalist = Cpanel::SysQuota::analyzerepquotadata();

    if ( ! $quotalist || ! ref $quotalist eq 'HASH' || ! keys %{$quotalist} ) {
        $logger->error("Unable to retrieve disk usage");
        return;
    }

    foreach my $user ( keys %{$quotalist} ) {
        my $real = $quotalist->{$user} * 1024;
        $report{users}->{$user}->{name}  = $user;
        $report{users}->{$user}->{space} = $real;
        $report{users}->{$user}->{owner} = $user2reseller->{$user};
        if ( $report{users}->{$user}->{owner} ) {
            $report{resellers}->{ $report{users}->{$user}->{owner} }->{usercount}++;
            if ( defined $report{resellers}->{ $report{users}->{$user}->{owner} }->{space} ) {
                $report{resellers}->{ $report{users}->{$user}->{owner} }->{space} += $real;
            } else {
                $report{resellers}->{ $report{users}->{$user}->{owner} }->{space} = $real;
            }
            push @{ $report{resellers}->{ $report{users}->{$user}->{owner} }->{users} }, $report{users}->{$user};
        }
    }
    return \%report;
}

sub load_resellers {
    my %user2reseller = ();    # hash for user -> reseller map

    if ( open my $trueuserowners_fh, '<', '/etc/trueuserowners' ) {
        while ( my $line = <$trueuserowners_fh> ) {
            if ( $line =~ m/^\s*(.*?):\s+(.*?)\s*$/xms ) {
                my $user     = $1;
                my $reseller = $2;
                $user2reseller{$user} = $reseller;
            }
        }
        close $trueuserowners_fh;
    } else {
        $logger->error("Unable to open '/etc/trueuserowners' for reading: $ERRNO");
    }

    return \%user2reseller;
}

sub user_isvalid {
    my $user = shift;

    # Verify that a username was provided.
    if ( ! $user ) {
        $logger->error('No user specified.');
        return;
    }

    # Verify that $user is a valid Linux user.
    if ( ! getpwnam($user) ) {
        $logger->error("'$user' does not appear to be a valid system user.");
        return;
    }

    # Verify that $user is a cpanel user.
    if ( ! -f "/var/cpanel/users/$user" ) {
        $logger->error("'$user' does not appear to be a valid cPanel user.");
        return;
    }
    return 1;
}

sub validate_ticket {
    my $ticket = shift;

    my $validation_checks = {
        'Enter ticket ID: ' => sub {
            if ( ticket_isvalid($_) ) {
                return 1;
            }
            $logger->error("Invalid ticket number specified.");
            return;
        }
    };

    if ( ! ticket_isvalid($ticket) ) {
        $ticket = IO::Prompt::prompt( 'Enter ticket ID: ', '-tty', '-require' => $validation_checks );
    }

    return uc($ticket);
}

sub ticket_isvalid {
    my $ticket = shift;
    my $ticket_regex = qr/([a-zA-Z]{3}\-)?[0-9]{8}/xmsi;

    if ( defined $ticket && $ticket =~ $ticket_regex ) {
        return 1;
    }

    return;
}

sub cp_ispatched {
    # Set the line at which version --skip-limit was used in pkgacct
    my $cp_last_patched_version = version->parse('11.42.0');

    # Get current cPanel version
    my $cp_version = version->parse(Cpanel::Version::getversionnumber());

    if ( ! $cp_version ) {
        $logger->error("Unable to determine cPanel version.");
    } elsif ( $cp_version > $cp_last_patched_version ) {
        return 1;
    }
    return;
}

sub skip_limits {
    my $user = shift || return;

    if ( ! -d '/etc/skipresbackup' && ! mkdir '/etc/skipresbackup' ) {
        $logger->error("Unable to create directory '/etc/skipresbackup': $!");
    } else {
        Cpanel::FileUtils::touchfile("/etc/skipresbackup/$user");
    }

    if ( -e "/etc/skipresbackup/$user" ) {
        return 1;
    }

    $logger->warn("Unable to skip backup size limits.");
    return;
}

__END__
