#!/usr/local/cpanel/3rdparty/bin/perl

use strict;

use Cpanel::ConfigFiles          ();
use Cpanel::EditHttpdconf        ();
use Cpanel::FileUtils::Write     ();
use Cpanel::LoadFile             ();
use Cpanel::PwCache              ();

sub _suspension_include_file {
    return "$Cpanel::ConfigFiles::httpd_conf_includes_dir/disable_user_httpd.conf";
}

sub _suspension_dir {
    if ( ! -d '/opt/eig_linux/var/suspended/' ) { system("mkdir -p /opt/eig_linux/var/suspended/"); }
    return '/opt/eig_linux/var/suspended/';
}

sub _test_legacy_include_dir {
    return '/usr/local/apache/conf/userdata/std/2/';
}

sub main {
    my @argv    = @_;
    if ( update_include(0) ) {
        system('service httpd graceful');
    }
    return 0;
}

sub update_include {
    my $convert                     = shift;
    my %original_suspended_docroots = ();
    my %retained_suspended_docroots = ();
    my %new_suspended_docroots      = ();
    my $suspension_contents = -e _suspension_include_file() ? Cpanel::LoadFile::loadfile( _suspension_include_file() ) : '';

    while ( $suspension_contents =~ /<Directory "([^\n]+)">\n/g ) {
        $original_suspended_docroots{$1} = undef;
    }

    Cpanel::PwCache::setpwent();
    while ( my @pw = Cpanel::PwCache::getpwent() ) {
        my ( $user, $uid, $gid, $homedir ) = @pw[ 0, 2, 3, 7 ];
        if ($convert) {
            remove_old_suspension_includes($user);
        }
        if ( -e _suspension_dir() . $user ) {

            if ( exists( $original_suspended_docroots{$homedir} ) ) {
                delete $original_suspended_docroots{$homedir};
                $retained_suspended_docroots{$homedir} = undef;
            }
            elsif ( exists( $retained_suspended_docroots{$homedir} ) ) {

                # Homedir is listed twice in /etc/passwd?
            }
            else {
                $new_suspended_docroots{$homedir} = undef;
            }
        }
    }

    # Intentionally ommitted since this generates warnings in testing
    # Cpanel::PwCache::endpwent();

    if ( !$suspension_contents || scalar keys %original_suspended_docroots || scalar keys %new_suspended_docroots ) {
        generate_include( keys %retained_suspended_docroots, keys %new_suspended_docroots );
        return 1;
    }
    return 0;
}

sub remove_old_suspension_includes {
    my $user = shift;

    if ( -e _test_legacy_include_dir() . "$user/$user-suspend.conf" ) {
        Cpanel::EditHttpdconf::del_vhost_include(
            {
                'user'                            => $user,
                'file'                            => "$user-suspend.conf",
                'ensure_vhost_include_directives' => 0,                      # The include line is left in the conf file. It will disappear during the next full rebuild
            }
        );
    }

    return;
}

sub generate_include {
    my @docroots         = @_;
    my $include_contents = <<EO_SUSPENSION_HEADER;
# This include file is automatically generated by
# /usr/local/cpanel/scripts/generate_account_suspension_include
# Any manual edits inside this file will be lost whenever account
# suspensions are updated.

RewriteEngine On

EO_SUSPENSION_HEADER

    foreach my $docroot ( sort @docroots ) {
        $include_contents .= <<EO_SUSPENSION;
<Directory "$docroot">
    AllowOverride none
    RedirectMatch ^/(?!cgi-sys/suspendedpage.cgi).* /cgi-sys/suspendedpage.cgi
</Directory>

EO_SUSPENSION
    }
    return Cpanel::FileUtils::Write::writefile( _suspension_include_file(), $include_contents, 0600 );
}


exit main(@ARGV) unless caller();
1;

