#!/usr/local/bin/perl
use strict;
use Fcntl qw(:DEFAULT :flock);
use File::Path;

my $readdir = '/var/lib/backup/';
my $logdir = '/var/log/datacycle/user_logs/';
mkpath($logdir) unless ( -d $logdir );
my %uids;

my @users;
open(my $DAT, '<', '/etc/trueuserdomains');
	while(<$DAT>) {
		chomp();
		if ( /^.*:\s([a-zA-Z0-9]+)$/ ) {
			my $user = $1;
			next if ( -f "/var/cpanel/suspended/$user" );
			push(@users, $user);
		}
	}
close($DAT);

my @files;
opendir(my $DIR, $readdir);
	while(my $dir = readdir($DIR)) {
		next unless ( $dir =~ /^[a-zA-Z0-9]+\.[0-9]{8}\.[0-9]{2}:[0-9]{2}:[0-9]{2}$/ );
		push(@files, $dir);
	}
closedir($DIR);

foreach my $user ( @users ) {
	print "Running against $user\n";
	$uids{$user} = getpwnam($user) unless ( defined($uids{$user}) );
	foreach my $file ( grep(/^$user/, @files) ) {
		open(my $DAT, '-|', '/usr/sbin/backup-events ' . $readdir . $file);
			while(<$DAT>) {
				chomp();
				if ( /^[A-Z]+\s+(\(write\)\s+)?(\([0-9\/]+\)):\s+(.*)$/ ) {
					my $file = $3;
					if ( $file !~ /\sto\s/ ) {
						make_entry($uids{$user}, $file);
					} else {
						my ( $file1, $file2 ) = split(' to ', $file);
						make_entry($uids{$user}, $file1);
						make_entry($uids{$user}, $file2);
					}
				}
			}
		close($DAT);
	}
}

sub make_entry {
	my ( $uid, $file ) = @_;
	open(my $DAT, '>>', $logdir . $uid);
	while ( ! flock($DAT, LOCK_NB|LOCK_EX) ) {
		close($DAT);
		sleep(1);
		open($DAT, '>>', $logdir . $uid);
	}
	my $timestamp = time();
	print $DAT "$timestamp:0:0:$uid:$file\n";
	close($DAT);
}
