#!/usr/bin/env perl

use warnings;
use strict;

use Getopt::Long;
use IPC::Open3;
use Config::General;
use DateTime;
use Data::Dumper;

my @defaultports = qw(53 953 80 443 8080 8443 3306 21 25 26 465 587 110 143 993 995 2077 2078 2082 2083 2084 2086 2087 2089 2095 2096 22 2222);

my %opts;
GetOptions( \%opts,  "port=s", "--ticket=s", "help" );
unless (  $opts{port} && ( $opts{port} =~ /\d+/ ) ) {
  print "You must specify a port.\n\n";
  usage();
  exit;
}

if ( grep { /^$opts{port}$/ } @defaultports ) {
  print "Error: " . $opts{port} . " is already open by default in the firewall.\n";
  exit;
}


add_to_ipset($opts{port}) or die "Failed to add " . $opts{port} . " to ipset.";
add_to_ports_local($opts{port}) or die "Added to ipset, but failed to add to ports_local.conf!";

my $date = DateTime->now();
$date->set_time_zone( 'America/Chicago' );
my $user = $ENV{'RUSER'} || 'unknown';
my $ticket = $opts{ticket} || 'not provided';
my $line = '[' . $date->mdy . ':' . $date->hms . '] ' . $user . ' ';
$line .= "opened port $opts{port} for ticket: $ticket\n";

open my $fh, '>>', '/var/log/firewall-modification.log' or die "Failed to open log file.";
print $fh $line;
close $fh;

sub add_to_ipset {
  my $port = shift;
  my $ipset = 'ports_out';

  my ($chld_in, $chld_out, $chld_err);
  use Symbol 'gensym'; $chld_err = gensym;
  my $pid = open3($chld_in, $chld_out, $chld_err, '/usr/sbin/ipset', '-exist', 'add', $ipset, $port);
  my @out = <$chld_out>;
  my @err = <$chld_err>;
  close $chld_in;
  close $chld_out;
  close $chld_err;
  waitpid ( $pid, 0 );
  my $stat = $? >> 8;
  return undef unless ( $stat == 0 );
  return 1; 
}

sub add_to_ports_local {
  my $port = shift;
  my $l = Config::General->new('/etc/firewall/conf/ports_local.conf');
  my $g = Config::General->new('/etc/firewall/conf/ports_global.conf');

  my %local = $l->getall();
  my %global = $g->getall();
  my @localout = split '\n', $local{output};
  my @localin = split '\n', $local{input};
  my @globalports = split '\n', $global{output};


  # as long as we're going to rewrite ipdrop_local, we may as well clear dupes
  my %temp = map { $_ => 1 } @localout;
  @localout = keys %temp;

  if ( grep { /^$port$/ } @globalports ) {
    print "$port already exists in ports_global.conf\n";
    exit 2;
  }

  if ( grep { /^$port$/ } @localout ) {
    print "$port already exists in ports_local.conf\n";
    exit 2;
  }

  push @localout, $port;
  open my $fh, '>', '/etc/firewall/conf/ports_local.conf.new';
  print $fh 'input << ENDOFINPUT' . "\n";
  print $fh "$_\n" for @localin;
  print $fh 'ENDOFINPUT' . "\n\n";
  print $fh 'output << ENDOFOUTPUT' . "\n";
  print $fh "$_\n" for @localout;
  print $fh 'ENDOFOUTPUT' . "\n\n";
  close $fh;
  rename '/etc/firewall/conf/ports_local.conf.new', '/etc/firewall/conf/ports_local.conf';
}

sub usage {
  print "openport - opens an outbound port\n";
  print "\t--port - port to open\n";
  print "\t--ticket - ticket id\n\n";
}

