#! /usr/local/cpanel/3rdparty/bin/perl
use lib '/usr/local/cpanel';
use Cpanel::MysqlUtils;
use Sys::Hostname;
use LWP::UserAgent;
use DBI;
use IO::Compress::Gzip qw(gzip);
use Fcntl qw(:flock);
use strict;
use warnings;
my $hostname = hostname;
my %wp; # db => tbl => user => docroot => wp_version => plugin_path => plugin_version
my %domain2path;
my %domain2user;
my %suspended;
my $dbfile = "/var/lib/eig/dc/plugins";
my $dbdir = "/var/lib/eig/dc";

open my $runonce, '<', $0 or die "Unable to open self for reading $0 : $!";
flock $runonce, LOCK_EX | LOCK_NB or exit;

sub userdatascan {
        open my $ud, '<', '/etc/userdatadomains' or die "Unable to open /etc/userdatadomains for reading : $!";
        while (defined(my $line = <$ud>)) {
                chomp $line;
                my ($domain, $data) = split /: /, $line, 2;
                my ($user, undef, undef, undef, $path) = split /==/, $data;
                $suspended{$user} = (-f "/var/cpanel/suspended/$user" ? 1 : 0) unless exists $suspended{$user};
                $domain2user{lc $domain} = $user;
                $domain2path{lc $domain} = $path;
        }
        close $ud;
}

sub confighasdb {
        my ($path, $db) = @_;
        open my $f, '<', "$path/wp-config.php" or return;
        my $user = getpwuid((stat($f))[4]);
        while (defined(my $line = <$f>)) {
                next unless $line =~ /define/ && $line =~ /DB_NAME/;
                return $user if $line =~ /\b\Q$db\E\b/;
        }
        return;
}

sub dbname { my $db = shift; $db =~ s/@(....)/chr(hex("0x$1"))/ge; return $db; }

sub tables {
        my @res;
        open my $p, '-|', qw(find -H /var/lib/mysql/ -maxdepth 2 -mindepth 2 -name *options.frm -type f)
                or die "Unable to open pipe to find : $!";
        while (defined(my $line = <$p>)) {
                next unless $line =~ m,^/var/lib/mysql/([^/]+)/([^/]+)\.frm$,;
                push @res, [map { dbname($_) } ($1, $2)];
        }
        close $p;
        @res;
}

sub pluginversion {
        my ($docroot, $path) = @_;
        open my $f, '<', "$docroot/wp-content/plugins/$path" or return "?";
        while (defined(my $line = <$f>)) {
                next unless $line =~ /Version:\s*([\d.]+)/;
                return $1;
        }
        return "?";
}

sub wp_version {
        my ($docroot) = @_;
        open my $f, '<', "$docroot/wp-includes/version.php" or return "?";
        while (defined(my $line = <$f>)) {
                next unless $line =~ /\$wp_version\D+([\d.]+)/;
                return $1;
        }
        return "?";
}

sub cwd {
        my ($db, $url) = @_;
        die "what kind of siteurl is this? $url"
                unless $url =~ m,^ https? :// ([^/]+) (/.*)? $,ix;
        my ($domain, $subdir) = (lc $1, $2);
        $subdir = "" unless defined $subdir;
        die "suspicious siteurl: $url" if $subdir =~ /\.\./;
        die "unknown domain in siteurl: $url" unless exists $domain2path{$domain};

        my $path = $domain2path{$domain}.$subdir;
        my $user = confighasdb($path, $db);
        return ($path, $user) if defined $user;

        $path = $domain2path{$domain};
        $user = confighasdb($path, $db);
        return ($path, $user) if defined $user;

        die "siteurl has unknown docroot : $url";
}

sub wpscan {
        my ($db, $tbl) = @_;
        my $dbh;
        eval {
                $dbh = DBI->connect("DBI:mysql:$db;mysql_socket=/var/lib/mysql/mysql.sock",
                        'root', Cpanel::MysqlUtils::getmydbpass('root'),
                        { RaiseError => 1, PrintError => 1 });
        };
        return if $@ || !$dbh;
        my $qtbl = $dbh->quote_identifier($tbl);
        my ($docroot, $user, @plugins, $siteurl);
        eval {
                my $res1 = $dbh->selectall_arrayref("select option_value from $qtbl where option_name='siteurl'");
                ($docroot, $user) = cwd($db, $siteurl = $res1->[0][0]) if defined($res1) && @$res1 > 0;
                my $res2 = $dbh->selectall_arrayref("select option_value from $qtbl where option_name='active_plugins'");
                @plugins = $res2->[0][0] =~ m,"([\w. /-]+)",g if defined($res2) && @$res2 > 0;
        };
        if ($@) { warn "gave up on $db $tbl : $@" }
        if (defined($docroot) && defined($user) && defined($siteurl) && @plugins) {
                my $wpver = wp_version($docroot);
                for my $path (@plugins) {
                        $wp{$db}{$tbl}{$user}{$siteurl}{$docroot}{$wpver}{$path} = pluginversion($docroot, $path);
                }
        }
}

sub send_wpinfo {
        my $post = '';
        for my $db (keys %wp) {
                for my $tbl (keys %{$wp{$db}}) {
                        for my $user (keys %{$wp{$db}{$tbl}}) {
                                for my $siteurl (keys %{$wp{$db}{$tbl}{$user}}) {
                                        for my $docroot (keys %{$wp{$db}{$tbl}{$user}{$siteurl}}) {
                                                for my $wpver (keys %{$wp{$db}{$tbl}{$user}{$siteurl}{$docroot}}) {
                                                        for my $path (keys %{$wp{$db}{$tbl}{$user}{$siteurl}{$docroot}{$wpver}}) {
                                                                my $vsn = $wp{$db}{$tbl}{$user}{$siteurl}{$docroot}{$wpver}{$path};
                                                                (my $plugin = $path) =~ s,/.*,,;
                                                                $post .= join("\t", $hostname, $db, $tbl, $user, $siteurl, $docroot, $wpver, $path, $plugin, $vsn, $suspended{$user} || 0)."\n";
                                                        }
                                                }
                                        }
                                }
                        }
                }
        }
        return unless $post;
	my $content;
	gzip \$post => \$content;
        my $ua = LWP::UserAgent->new;
        $ua->agent('plugin-potteryreporter');
        $ua->ssl_opts(verify_hostname => 0);
        $ua->post('https://scripts.hostgator.com/~sec/reporting/plugin.d?'.$hostname, Content => $content);
}

sub update_sqlite {
        my $plugins = 0;
        system "mkdir", "-p", $dbdir unless -d $dbdir;
        chmod 0600, $dbdir;
        my $dbh = DBI->connect("dbi:SQLite:dbname=$dbfile.new", undef, undef, { RaiseError => 1 });
        $dbh->do(<<'SQL');
CREATE TABLE plugins (
        host TEXT NOT NULL,
        db TEXT NOT NULL,
        tbl TEXT NOT NULL,
        user TEXT NOT NULL,
        siteurl TEXT NOT NULL,
        root TEXT NOT NULL,
        wpver TEXT NOT NULL,
        ppath TEXT NOT NULL,
        plugin TEXT NOT NULL,
        pver TEXT NOT NULL,
        suspended INT NOT NULL
);
SQL
        $dbh->do('CREATE INDEX idx_plugin on plugins(plugin)');
        $dbh->do('BEGIN TRANSACTION');
        for my $db (keys %wp) {
                for my $tbl (keys %{$wp{$db}}) {
                        for my $user (keys %{$wp{$db}{$tbl}}) {
                                for my $siteurl (keys %{$wp{$db}{$tbl}{$user}}) {
                                        for my $docroot (keys %{$wp{$db}{$tbl}{$user}{$siteurl}}) {
                                                for my $wpver (keys %{$wp{$db}{$tbl}{$user}{$siteurl}{$docroot}}) {
                                                        for my $path (keys %{$wp{$db}{$tbl}{$user}{$siteurl}{$docroot}{$wpver}}) {
                                                                my $vsn = $wp{$db}{$tbl}{$user}{$siteurl}{$docroot}{$wpver}{$path};
                                                                (my $plugin = $path) =~ s,/.*,,;
                                                                $dbh->do('INSERT INTO plugins VALUES (?, ?, ?, ?, ?, ?, ?, ?, ?, ?, ?)', {}, $hostname, $db, $tbl, $user, $siteurl, $docroot, $wpver, $path, $plugin, $vsn, $suspended{$user} || 0);
                                                                $plugins++;
                                                        }
                                                }
                                        }
                                }
                        }
                }
        }
        $dbh->do('COMMIT');
        $dbh->disconnect();
        if ($plugins) {
                rename "$dbfile.new" => $dbfile;
                chmod 0640, $dbfile;
        } else {
                unlink "$dbfile.new";
        }
}

open STDERR, '>', '/dev/null' unless -t \*STDIN;
userdatascan();
wpscan(@$_) for tables();
send_wpinfo();
update_sqlite();
