#! /usr/bin/env perl
use Sys::Hostname;
use LWP::UserAgent;
use IO::Compress::Gzip qw(gzip);
use Fcntl qw(:flock);
use YAML qw(LoadFile);
use strict;
use warnings;
my $hostname = hostname;
my %data; # domain => subdomain => ip => zapped
my (%domain2user, %domain2owner);
my %suspended;
my ($brand, $hostgroup) = ('', '');
open my $runonce, '<', $0 or die "Unable to open self for reading $0 : $!";
flock $runonce, LOCK_EX | LOCK_NB or exit;
eval {
    my $puppet = LoadFile("/opt/eig_linux/etc/account_pl.yaml");
    $brand = $puppet->{organization} if defined $puppet->{organization};
    $hostgroup = $puppet->{hostgroup} if defined $puppet->{hostgroup};
};

sub userdatascan {
    open my $ud, '<', '/etc/userdatadomains' or die "Unable to open /etc/userdatadomains for reading : $!";
    while (defined(my $line = <$ud>)) {
        chomp $line;
        my ($domain, $ddata) = split /: /, $line, 2;
        my ($user, $owner, undef, undef, $path) = split /==/, $ddata;
        $owner = '' if $owner eq "root";
        $suspended{$user} = (-f "/var/cpanel/suspended/$user" ? 1 : 0) unless exists $suspended{$user};
        $domain2user{lc $domain} = $user;
        $domain2owner{lc $domain} = $owner;
    }
    close $ud;
}

sub scan_zones {
    for my $zone (</var/named/*.db>) {
        next unless $zone =~ m,.*/([\w.]+)\.db$,;
        my $domain = $1;
        open my $f, '<', $zone or next;
        while (defined(my $line = <$f>)) {
            next unless $line =~ /^(\s*;\s*)?(\w+).*\b(\Q217.8.117.8\E|50\.31\.\d+\.\d+)\s*$/;
            my ($zapped, $subdomain, $ip) = ($1, $2, $3);
            $data{$domain}{$subdomain}{$ip}{(defined $zapped ? 1 : 0)} = 1;
        }
        close $f;
    }
}

sub send_report {
    my $post = '';
    for my $domain (keys %data) {
        for my $subdomain (keys %{$data{$domain}}) {
            for my $ip (keys %{$data{$domain}{$subdomain}}) {
                for my $zapped (keys %{$data{$domain}{$subdomain}{$ip}}) {
                    my $user = exists $domain2user{$domain} ? $domain2user{$domain} : "";
                    my $owner = exists $domain2owner{$domain} ? $domain2owner{$domain} : "";
                    my $suspended = $suspended{$domain} ? 1 : 0;
                    $post .= join("\t", $hostname, $brand, $hostgroup, $domain, $subdomain, $ip, $zapped, $user, $owner, $suspended)."\n";
                }
            }
        }
    }
    return unless length($post);
    my $content;
    gzip \$post => \$content;
    my $ua = LWP::UserAgent->new;
    $ua->agent('spammybear-potteryreporter');
    $ua->ssl_opts(verify_hostname => 0);
    $ua->post('https://scripts.hostgator.com/~sec/reporting/spammybear.nim?'.$hostname, Content => $content);
}

open STDERR, '>', '/dev/null' unless -t \*STDIN;
userdatascan();
scan_zones();
send_report();
