#! /usr/bin/env perl
use Sys::Hostname;
use strict;
use warnings;
my $problems = 0;
my @procs;

my $date=`date "+%F %T (%Z) [%s epoch]"`;
chomp($date);

my $logfile="/opt/eig_linux/log/unsafe_root_procs.log";
my $logtxt;
open(my $LOGFILE, '>', \$logtxt) or warn "Couldn't open scalar for writing : $!";

print $LOGFILE "Log for last run at $date\n";
print $LOGFILE "========================================================\n\n";
opendir my $d, '/proc';
while (defined(my $pid = readdir $d)) {
    next unless -o "/proc/$pid";
    check_exe($pid);
    check_cmdline($pid);
}
print $LOGFILE "\n========================================================\n";
close($LOGFILE);
report($problems);

sub check_exe {
    my ($pid) = @_;
    my $script = readlink "/proc/$pid/exe" or return;
    return unless $script =~ m,^(/home\d*/[^/]+/),;
    my $homedir = $1;
    return if -o $homedir;
    print STDERR "root proc under user dir: $script\n" if -t \*STDERR;
    print $LOGFILE "root proc under user dir: $script\n";
    push @procs, $script;
    $problems++;
}

sub check_cmdline {
    my ($pid) = @_;
    open my $f, '<', "/proc/$pid/cmdline" or return;
    my @cmd = split /\0/, scalar(<$f>);
    close $f;
    return unless @cmd >= 2
        && $cmd[0] =~ m,(?:sh|bash|perl|ruby|php|python|lua|tclsh|awk)$,
        && $cmd[1] =~ m,^(/home\d*/[^/]+/),;
    my $homedir = $1;
    return if -o $homedir;
    print STDERR "root script under user dir: @cmd\n" if -t \*STDERR;
    print $LOGFILE "root script under user dir: @cmd\n";
    my $script = $cmd[1];
    push @procs, $script;
    $problems++;
}

sub report {
    my ($flag) = @_;
    my $root_procs = join(',', @procs);
    $root_procs = 'None' if(!$root_procs);
    if ($flag) {
        open my $log, '>', $logfile or warn "Unable to open $logfile for writing : $!";
        print {$log} $logtxt;
        close $log;
    }
    exec "/usr/bin/zabbix_sender -c /etc/zabbix/zabbix_agentd.conf -s '@{[hostname()]}' -k eig.user.root_process -o $flag >/dev/null 2>/dev/null";

    exec "/usr/bin/zabbix_sender -c /etc/zabbix/zabbix_agentd.conf -s '@{[hostname()]}' -k eig.user.root_procs -o $root_procs >/dev/null 2>/dev/null";
}
