#!/usr/bin/perl
use Sys::Hostname;
use LWP::UserAgent;
use Digest::MD5 qw(md5_hex);
use strict;
use warnings;
my $hostname = hostname();
my $output = '';

open my $f, '<', '/etc/userdatadomains' or exit;
while (defined(my $line = <$f>)) {
	next unless $line =~ /^([^:]+): ([^=]+)==([^=]+)/;
	my ($domain, $user, $owner) = ($1, $2, $3);
	if (suspect($domain) && alive($user)) {
		my $user_age = age($user);
		$user .= ":$user_age" if $user_age;
		$output .= "$user $owner $domain\n";
	}
}

exit unless $output ne '';
my $key = md5_hex("-a9swdfjzosdkjxx:$hostname");
my $ua = LWP::UserAgent->new;
$ua->ssl_opts(verify_hostname => 0);
$ua->timeout(60);
my $req = HTTP::Request->new(POST => "https://192.185.0.115/~sec/suspdomains/log.cgi?host=$hostname&key=$key");
$req->content_type('text');
$req->content($output);
$ua->request($req);

sub suspect {
	my ($domain) = @_;
	return $domain =~
		/ app[li]e [il]d
		| \bapp[li]e[.-]com
		| paypa[ilt]
		| western.*un[il]on
		| itunes.*connect
		| we[il][il]sfargo
		| bankofamerica
		| facebook[.-]com
		| (?:accounts|drive)[.-]google[.-]com
		| \bpeypal[.-]com
		| \bchase[.-]com
		| \bdropbox[.-]com
		| ^htt?ps?[.-]www
		| capitalone1[.-]com
		| \bitunes[.-]confirm
		| \blogin[.-]live[.-]com
		| americanexpress[.-]com
		| store[.-]steampowered[.-]com
		| my[.-]bluehost
		| portal[.-]hostgator
		| (?: (?:[^-]  - [^-]+){6} )
	/ix || too_many_dots($domain)
}

sub too_many_dots {
	my ($domain) = @_;
	my $dots =()= $domain =~ /([^.]{4,} \. (?=[^.]+))/gx;
	return $dots > 4
}

my %alive;
sub alive {
	my ($user) = @_;
	return $alive{$user} if exists $alive{$user};
	$alive{$user} = ! -f "/var/cpanel/suspended/$user";
}
my %age;
sub age {
	my ($user) = @_;
	return $age{$user} if exists $age{$user};
	open my $f, '<', "/var/cpanel/users/$user" or return;
	while (defined(my $line = <$f>)) {
		next unless $line =~ /^STARTDATE=(\d+)/;
		return $age{$user} = $1;
	}
	$age{$user} = undef;
}
