#!/usr/bin/perl
# $Date: 2025-09-04 $
# $Revision: 2.3.1 $
# $Source: /root/bin/submitsh $
# $Author: Julian Fondren $
# Submit shells to Julian Fondren for Updating Scan
# https://reports.soc.newfold.com/dash/wiki/help/submitsh
# (C) 2025 - Newfold Digital Inc.
use strict;
use warnings;
use version; our $VERSION = qv('3.1');
use Getopt::Long;
use Digest::MD5 qw(md5_hex);
use LWP::Simple;
use Sys::Hostname;
use File::Slurp;
use IO::Compress::Gzip qw(gzip);

my $hostname = hostname;
my ($false, $sig);

GetOptions(
    'false|f' => \$false,
    'sig=s' => \$sig,
) or usage();
$false = $false ? "true" : "false";
$sig = randsig(9) unless defined $sig;
die "bad signature, must be < 64 simple chars" if $sig !~ /^[a-zA-Z0-9-]{1,63}$/;

if (defined($ARGV[0])) {
    do_submit($ARGV[0]);
} else {
    usage();
}

sub do_submit {
    my ($file) = @_;
    my ($content, $md5, $size);
    {
        my $malware = read_file($file);
        $size = length($malware);
        $md5 = md5_hex($malware);
        gzip \$malware => \$content;
    }
    my @stats = stat $file;
    my $user = getpwuid $stats['4'];
    my $ruser = defined($ENV{'RUSER'}) ? $ENV{'RUSER'}
        : defined($ENV{'SYSADMIN'}) ? $ENV{'SYSADMIN'}
        : 'unk';

    my $ua = LWP::UserAgent->new;
    $ua->agent('submitsh-potteryreporter');
    $ua->ssl_opts(verify_hostname => 0);
    my $res = $ua->post('https://reports.soc.newfold.com/report/submitsh?'
        ."server=$hostname&md5=$md5&user=$user&false=$false&key=87__poiKJln&ruser=$ruser&sig=$sig&size=$size",
        Content => $content);
    if ($res->is_success) {
        print "Report submitted for $file ($md5:$size:$sig)\n";
    } else {
        die "Failed to send report: ".$res->content;
    }
}

sub usage {
    die <<'END_USAGE';

  Usage: submitsh [OPTIONS] FILENAME
  Options:
    --false, -f     Mark as false positive
    --sig=SIG       Provide a signature name (customers are likely to see this)
    --help, -h      Show this usage

END_USAGE
}

# Customers can see this, so avoid vowels (and smaller $n) so we don't
# accidentally spell anything.
sub randsig {
    my ($n) = @_;
    my @let = split //, "BCDFGHJKLMNPQRSTVWXYZ";
    my $pre = join '', map { $let[rand @let] } 0..$n;
    my $post = 5000+int(rand(15000));
    return "NF-$pre-$post";
}
