#!/usr/bin/env perl

use warnings;
use strict;

use Getopt::Long;
use IPC::Open3;
use Config::General;
use DateTime;
use Data::Dumper;

my %opts;
GetOptions( \%opts,  "ip=s", "port=s", "--ticket=s", "help" );
unless (  $opts{ip} && ( $opts{ip} =~ /\d+\.\d+\.\d+\.\d+/ ) && $opts{port} && ($opts{port} =~ /\d+/) ) {
  print "You must specify an ip address and port.\n\n";
  usage();
  exit;
}

unless ( `/sbin/ip a` =~ /$opts{ip}/ ) {
  print "IP address ($opts{ip}) does not exist on this server.\n\n";
  usage();
  exit;
}

add_to_ports_whitelist($opts{ip}, $opts{port});
restart_if_needed();

my $date = DateTime->now();
$date->set_time_zone( 'America/Chicago' );
my $user = $ENV{'RUSER'} || 'unknown';
my $ticket = $opts{ticket} || 'not provided';
my $line = '[' . $date->mdy . ':' . $date->hms . '] ' . $user . ' ';
$line .= "added $opts{ip}:$opts{port} to ports_whitelist for ticket: $ticket\n";

open my $fh, '>>', '/var/log/firewall-modification.log' or die "Failed to open log file.";
print $fh $line;
close $fh;


sub add_to_ports_whitelist {
  my $ip = shift;
  my $port = shift;
  my $conf = '/etc/firewall/conf/ports_whitelist.conf';
  my @lines;

  if ( -f $conf ) {
    open my $fh, '<', $conf or die("cannot open $conf");
    @lines = <$fh>;
    close $fh;
  }
  push @lines, "$ip:$port\n";
  
  open my $fh, '>', "$conf.new" or die("cannot open $conf.new for writing");
  print $fh $_ foreach @lines;
  close $fh;

  rename '/etc/firewall/conf/ports_whitelist.conf.new', '/etc/firewall/conf/ports_whitelist.conf';
}

sub restart_if_needed {
  print "restarting firewall .. ";
  my ($chld_in, $chld_out, $chld_err);
  use Symbol 'gensym'; $chld_err = gensym;
  my $pid = open3($chld_in, $chld_out, $chld_err, '/etc/init.d/firewall', 'restart');
  my @out = <$chld_out>;
  my @err = <$chld_err>;
  close $chld_in;
  close $chld_out;
  close $chld_err;
  waitpid ( $pid, 0 );
  my $stat = $? >> 8;
  if ( $stat == 0 ) {
    print "done\n";
  }
  else {
    print "Failed restarting firewall. Manually check this!\n";
  }
}

sub usage {
  print "bh-openport - opens a inbound port to a specific ip address\n";
  print "\t--ip - ip to whitelist\n";
  print "\t--port - port to whitelist\n";
  print "\t--ticket - ticket id\n\n";
}


