#!/usr/bin/perl
use strict;
use warnings;

use YAML 'LoadFile';
use File::Spec::Functions qw(catdir);
use File::Path qw(make_path remove_tree);
use Data::Dumper;
use Sys::Hostname;
use Getopt::Long;

my $verbose = 0;
my $logs_only = 0;
my $account_only = 0;
my $usage = 0;
my $no_cleanup = 0;
my @domains;
my $user;
GetOptions(
    "user|u=s"    => \$user,
    "verbose|v"    => \$verbose,
    "logs-only"    => \$logs_only,
    "no-cleanup"    => \$no_cleanup,
    "domain|d=s"    => \@domains,
    "acccount-only"    => \$account_only,
    "help|usage|h"    => \$usage,

);
usage() if $usage;
usage("Please pass in user with --user") if not defined $user and not @domains;

my $green = "\033[1;32m";
my $red = "\033[1;31m";
my $normal = "\033[0m";

if (@domains && !$user) {
    chomp($user = qx(/scripts/whoowns $domains[0]));
    die "Unable to find user for $domains[0]\n" if $?;
} else {
    die "No userdata found for $user" if ! -f "/var/cpanel/userdata/$user/main";
    my $userdata = LoadFile("/var/cpanel/userdata/$user/main");
    push @domains, $userdata->{'main_domain'};
    foreach my $dom (keys %{$userdata->{'addon_domains'}}){ push @domains, $dom };
    foreach my $dom (@{$userdata->{'parked_domains'}}){ push @domains, $dom };
}
my $cust_home = (getpwnam($user))[7] or die "Unable to find info for user $user\n";
my $backup_num  = $1 if ($cust_home =~ /home(\d?)/x);
my $backup_conf = LoadFile('/opt/eig_linux/etc/backup_server_info.conf');
my $part = best_partition();
my $staging_dir = "$part/preserve_account_staging/$user/";
print "$green\nStaging at $staging_dir\n$normal";
make_path($staging_dir) if not -d $staging_dir;
my $hostname = hostname;


#Grab logs
if (!$account_only){
    print "$green\nProcessing Logs\n$normal";
    apache_logs();
    exim_logs();
    ftp_logs();
    cpanel_logs();
}

#copy account files
if (!$logs_only) {
    print "$green\nProcessing homedir and backups\n$normal";
    my $rsync = "ionice -c2 -n6 rsync -x -rlptgo -e \"ssh -i /admin/hgbackupdir/backupkey\"";
    mkdir "$staging_dir/$user.non-home-data" if ! -d "$staging_dir/$user.non-home-data";
    my @commands = (
        "/scripts/pkgacct --skiphomedir $user $staging_dir/$user.non-home-data backup",
        "ionice -c2 -n6 cp --preserve=links -xpr $cust_home $staging_dir/$user.home",
        "$rsync --exclude=homedir/ $backup_conf->{'backup_ip'}:/home/$hostname/backup$backup_num/cpbackup/seed/$user/ $staging_dir/$user.seed",
        "$rsync --link-dest=$staging_dir/$user.home $backup_conf->{'backup_ip'}:/home/$hostname/backup$backup_num/cpbackup/seed/$user/homedir/ $staging_dir/$user.seed/homedir/",
        "$rsync --link-dest=$staging_dir/$user.seed $backup_conf->{'backup_ip'}:/home/$hostname/backup$backup_num/cpbackup/daily/$user/ $staging_dir/$user.daily/",
        "$rsync --link-dest=$staging_dir/$user.seed $backup_conf->{'backup_ip'}:/home/$hostname/backup$backup_num/cpbackup/weekly/$user/ $staging_dir/$user.weekly/",
        "$rsync --link-dest=$staging_dir/$user.seed $backup_conf->{'backup_ip'}:/home/$hostname/backup$backup_num/cpbackup/monthly/$user/ $staging_dir/$user.monthly/",
        );
    foreach my $c (@commands){ run($c); }
}

#Tar up content then clean up
print "$green\nTarring up Archive\n$normal";
run("ionice -c2 -n6 tar -czf $staging_dir/../$user.tar.gz -C $staging_dir $user.non-home-data $user.home $user.seed $user.daily $user.weekly $user.monthly $user.logs");

if (!$no_cleanup) {
    print "$green\nCleaning up $staging_dir\n$normal";
    remove_tree($staging_dir);
}

print "$green\nFinished$normal\nTar: $part/preserve_account_staging/$user.tar.gz\n";

# Time to move it to the legal nas server, we haven't figured this out yet, but likely we get an unprivelged user to rsync to.


#subs belong at the bottom
sub apache_logs {
    make_path "$staging_dir/$user.logs" if ! -d "$staging_dir/$user.logs";
    run("rsync -av /usr/local/apache/domlogs/$user/ $staging_dir/$user.logs/apache_logs/");
    run("rsync -av /home/apachelogs/$user/ '$staging_dir/$user.logs/apache_archives/'") if -d "/home/apachelogs/$user";
}

sub exim_logs {
    my $log_path = '/var/log/';
    my $log_dest = "$staging_dir/$user.logs/exim_logs";
    make_path "$log_dest" if ! -d "$log_dest";
    my $log_name = 'exim_mainlog';
    my @logs = glob("$log_path/$log_name*");
    foreach my $log (@logs){
    my $dom_regex = sprintf("'(%s)'",join('|',@domains));
        run("exigrep $dom_regex $log >> $log_dest/exim_mainlog");
    }
}

sub ftp_logs {
    my $log_path = '/var/log/';
    my $log_dest = "$staging_dir/$user.logs/ftp_logs";
    make_path "$log_dest" if ! -d "$log_dest";
    my $log_name = 'messages';
    my @logs = glob("$log_path/$log_name*");
    foreach my $log (@logs){
        my $grep = $log =~ /gz$/ ? 'zgrep' : 'grep';
        run("$grep -E 'pure-ftpd.*?/home[0-9]?/$user' $log >> $log_dest/$user");
    }
}

sub cpanel_logs {
    my $log_path = '/usr/local/cpanel/logs';
    my $log_dest = "$staging_dir/$user.logs/cpanel_logs";
    make_path "$log_dest" if ! -d "$log_dest";
    my $log_name = 'access_log';
    my @logs = glob("$log_path/$log_name*");
    foreach my $log (@logs){
        my $grep = $log =~ /gz$/ ? 'zgrep' : 'grep';
    my $dom_regex = sprintf("'(%s|%s)'",join('|',@domains),$user);
        run("$grep -E $dom_regex $log >> $log_dest/access_log");
    }
}

sub best_partition {
    my @df = qx(df -P|sed 1d);
    my @passwd = getpwnam($user);
    my $users_home = $1 if $passwd[7] =~ m|^(/home\d*)/|;
    my @quotas = qx(repquota $users_home);
    my $estimated_usage;
    foreach my $line (@quotas) {
        chomp($line);
        my ($quota_user, undef, $used) = split('\s+', $line);
        if ($quota_user eq $user){
            $estimated_usage = $used * 3;
            last;
        }
    }
    my $best = {'available' => 0};
    foreach my $line (@df) {
        chomp($line);
        my (undef, undef, undef, $available, undef, $mountpoint) = split('\s+', $line);
        next unless (defined $mountpoint && $mountpoint =~ m|^/home\d?$|);
        if ($available > $best->{'available'}){
            $best->{'available'} = $available;
            $best->{'mountpoint'} = $mountpoint;
        }
    }
    die "No partition found with enough space\n" if (! defined $best->{'mountpoint'} || $estimated_usage >= $best->{'available'});
    return $best->{'mountpoint'};
}

sub run {
    my $cmd = shift;
    print "Running: $cmd\n" if $verbose;
    system("$cmd") == 0 or warn "Bad exit: $cmd";
    return;
}

sub usage {
    my $msg = shift // "";
    my $help  = q(Usage:
    This Script is meant to tar up all logs and backups and current data for an account for preservation.
        --user|u=USER              The customer we are preserving account data for
    --domain|d=DOMAIN    The domain we need data for (if no user is given)
    --logs-only        Only tar up logs for the account
    --account-only        only tar up account files (including homedir)
    --verbose|v        Turn on more verbose reporting
    --no-cleanup        Don't clean up the files after tarring them
        --help                  Prints this message.
);
    print "$help" . "\n$msg\n\n";
    exit;
}
